(Xojo Plugin) Upload File from String

Uploads a text file where the contents of the file are contained in a string variable.

See Google Drive Files: create for more details.

Also See Google Drive Multipart Upload for more details.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

Dim success As Boolean
success = True

// It requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

// This example uses a previously obtained access token having permission for the 
// Google Drive scope.

Dim gAuth As New Chilkat.AuthGoogle
gAuth.AccessToken = "GOOGLE-DRIVE-ACCESS-TOKEN"

Dim rest As New Chilkat.Rest

// Connect using TLS.
Dim bAutoReconnect As Boolean
bAutoReconnect = True
success = rest.Connect("www.googleapis.com",443,True,bAutoReconnect)

// Provide the authentication credentials (i.e. the access token)
success = rest.SetAuthGoogle(gAuth)

// A multipart upload to Google Drive needs a multipart/related Content-Type
success = rest.AddHeader("Content-Type","multipart/related")

// Specify each part of the request.

// The 1st part is JSON with information about the file.
rest.PartSelector = "1"
success = rest.AddHeader("Content-Type","application/json; charset=UTF-8")

Dim json As New Chilkat.JsonObject
success = json.AppendString("name","helloWorld.txt")
success = json.AppendString("description","A simple text file that says Hello World.")
success = json.AppendString("mimeType","text/plain")
success = rest.SetMultipartBodyString(json.Emit())

// The 2nd part is the file content.
// In this case, we'll upload a simple text file containing "Hello World!"
rest.PartSelector = "2"
success = rest.AddHeader("Content-Type","text/plain")

Dim fileContents As String
fileContents = "Hello World!"
success = rest.SetMultipartBodyString(fileContents)

Dim jsonResponse As String
jsonResponse = rest.FullRequestMultipart("POST","/upload/drive/v3/files?uploadType=multipart")
If (rest.LastMethodSuccess <> True) Then
    System.DebugLog(rest.LastErrorText)
    Return
End If

// A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    System.DebugLog("response status code = " + Str(rest.ResponseStatusCode))
    System.DebugLog("response status text = " + rest.ResponseStatusText)
    System.DebugLog("response header: " + rest.ResponseHeader)
    System.DebugLog("response JSON: " + jsonResponse)
    Return
End If

// Show the JSON response.
success = json.Load(jsonResponse)

// Show the full JSON response.
json.EmitCompact = False
System.DebugLog(json.Emit())

// A successful response looks like this:
// {
//   "kind": "drive#file",
//   "id": "0B53Q6OSTWYoldmJ0Z3ZqT2x5MFk",
//   "name": "Untitled",
//   "mimeType": "text/plain"
// }

// Get the fileId:
System.DebugLog("fileId: " + json.StringOf("id"))