Xojo Plugin
Xojo Plugin
Google Contacts - Retrieve as JSON
See more Google APIs Examples
Demonstrates how to retrieve Google Contacts as JSON.Chilkat Xojo Plugin Downloads
Dim success As Boolean
success = False
// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.
// --------------------------------------------------------------------------------------------------------
// Note: The code for setting up the Chilkat REST object and making the initial connection can be done once.
// Once connected, the REST object may be re-used for many REST API calls.
// (It's a good idea to put the connection setup code in a separate function/subroutine.)
// --------------------------------------------------------------------------------------------------------
// It is assumed we previously obtained an OAuth2 access token.
// This example loads the JSON access token file
// saved by this example: Get Google Contacts OAuth2 Access Token
Dim jsonToken As New Chilkat.JsonObject
success = jsonToken.LoadFile("qa_data/tokens/googleContacts.json")
If (success <> True) Then
System.DebugLog("Failed to load googleContacts.json")
Return
End If
Dim gAuth As New Chilkat.AuthGoogle
gAuth.AccessToken = jsonToken.StringOf("access_token")
Dim rest As New Chilkat.Rest
// Connect using TLS.
Dim bAutoReconnect As Boolean
bAutoReconnect = True
success = rest.Connect("www.google.com",443,True,bAutoReconnect)
// Provide the authentication credentials (i.e. the access token)
success = rest.SetAuthGoogle(gAuth)
// ----------------------------------------------
// OK, the REST connection setup is completed..
// ----------------------------------------------
// To retrieve the contacts, we need to send the following:
// GET /m8/feeds/contacts/default/full
// GData-Version: 3.0
// To get the contacts data in JSON format, set the "alt" query parameter to "json"
success = rest.AddQueryParam("alt","json")
success = rest.AddHeader("GData-Version","3.0")
Dim sbResponseBody As New Chilkat.StringBuilder
success = rest.FullRequestNoBodySb("GET","/m8/feeds/contacts/default/full",sbResponseBody)
If (success <> True) Then
System.DebugLog(rest.LastErrorText)
Return
End If
// A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
System.DebugLog("response status code = " + Str(rest.ResponseStatusCode))
System.DebugLog("response status text = " + rest.ResponseStatusText)
System.DebugLog("response header: " + rest.ResponseHeader)
System.DebugLog("response body: " + sbResponseBody.GetAsString())
Return
End If
// If the 200 response was received, then the contacts JSON is contained
// in the response body.
Dim json As New Chilkat.JsonObject
success = json.LoadSb(sbResponseBody)
json.EmitCompact = False
// Save the pretty-printed JSON response to a file.
sbResponseBody.Clear
success = json.EmitSb(sbResponseBody)
success = sbResponseBody.WriteFile("qa_output/google_contacts.json","utf-8",False)
// Parse the Google Contacts JSON, and iterate over the contacts..
Dim totalResults As Int32
totalResults = json.IntOf("feed.openSearch$totalResults.$t")
Dim startIndex As Int32
startIndex = json.IntOf("feed.openSearch$startIndex.$t")
Dim itemsPerPage As Int32
itemsPerPage = json.IntOf("feed.openSearch$itemsPerPage.$t")
System.DebugLog("totalResults = " + Str(totalResults))
System.DebugLog("startIndex = " + Str(startIndex))
System.DebugLog("itemsPerPage = " + Str(itemsPerPage))
Dim numEntries As Int32
numEntries = json.SizeOfArray("feed.entry")
Dim i As Int32
i = 0
While i < numEntries
json.I = i
System.DebugLog(Str(i + 1) + " ----")
System.DebugLog("title: " + json.StringOf("feed.entry[i].title.$t"))
Dim fullName As String
fullName = json.StringOf("feed.entry[i].gd$name.gd$fullName.$t")
If (json.LastMethodSuccess = True) Then
System.DebugLog("fullName: " + fullName)
End If
// There can be multiple email addresses, so it's stored as a JSON array..
Dim numEmailAddresses As Int32
numEmailAddresses = json.SizeOfArray("feed.entry[i].gd$email")
Dim j As Int32
j = 0
While j < numEmailAddresses
Dim emailAddress As String
emailAddress = json.StringOf("feed.entry[i].gd$email[j].address")
If (json.LastMethodSuccess = True) Then
System.DebugLog("email address: " + emailAddress)
End If
j = j + 1
Wend
i = i + 1
Wend
// A sample Google Contacts JSON response:
// {
// "version": "1.0",
// "encoding": "UTF-8",
// "feed": {
// "xmlns": "http://www.w3.org/2005/Atom",
// "xmlns$openSearch": "http://a9.com/-/spec/opensearch/1.1/",
// "xmlns$gContact": "http://schemas.google.com/contact/2008",
// "xmlns$batch": "http://schemas.google.com/gdata/batch",
// "xmlns$gd": "http://schemas.google.com/g/2005",
// "gd$etag": "\"QHw5eTVSLyt7I2A9XRFaE0kNTwI.\"",
// "id": {
// "$t": "chilkat.support@gmail.com"
// },
// "updated": {
// "$t": "2016-11-17T01:57:41.221Z"
// },
// "category": [
// {
// "scheme": "http://schemas.google.com/g/2005#kind",
// "term": "http://schemas.google.com/contact/2008#contact"
// }
// ],
// "title": {
// "$t": "Chilkat Support's Contacts"
// },
// "link": [
// {
// "rel": "alternate",
// "type": "text/html",
// "href": "https://www.googleapis.com/"
// },
// {
// "rel": "http://schemas.google.com/g/2005#feed",
// "type": "application/atom+xml",
// "href": "https://www.googleapis.com/m8/feeds/contacts/chilkat.support%40gmail.com/full"
// },
// {
// "rel": "http://schemas.google.com/g/2005#post",
// "type": "application/atom+xml",
// "href": "https://www.googleapis.com/m8/feeds/contacts/chilkat.support%40gmail.com/full"
// },
// {
// "rel": "http://schemas.google.com/g/2005#batch",
// "type": "application/atom+xml",
// "href": "https://www.googleapis.com/m8/feeds/contacts/chilkat.support%40gmail.com/full/batch"
// },
// {
// "rel": "self",
// "type": "application/atom+xml",
// "href": "https://www.googleapis.com/m8/feeds/contacts/chilkat.support%40gmail.com/full?max-results=25&alt=json"
// },
// {
// "rel": "next",
// "type": "application/atom+xml",
// "href": "https://www.googleapis.com/m8/feeds/contacts/chilkat.support%40gmail.com/full?max-results=25&alt=json&start-index=26"
// }
// ],
// "author": [
// {
// "name": {
// "$t": "Chilkat Support"
// },
// "email": {
// "$t": "chilkat.support@gmail.com"
// }
// }
// ],
// "generator": {
// "version": "1.0",
// "uri": "http://www.google.com/m8/feeds",
// "$t": "Contacts"
// },
// "openSearch$totalResults": {
// "$t": "350"
// },
// "openSearch$startIndex": {
// "$t": "1"
// },
// "openSearch$itemsPerPage": {
// "$t": "25"
// },
// "entry": [
// {
// "id": {
// "$t": "http://www.google.com/m8/feeds/contacts/chilkat.support%40gmail.com/base/0"
// },
// "gd$etag": "\"SX8zcTVSLyt7I2A9WxBXFU4MQwI.\"",
// "updated": {
// "$t": "2010-01-26T20:07:48.189Z"
// },
// "app$edited": {
// "xmlns$app": "http://www.w3.org/2007/app",
// "$t": "2010-01-26T20:07:48.189Z"
// },
// "category": [
// {
// "scheme": "http://schemas.google.com/g/2005#kind",
// "term": "http://schemas.google.com/contact/2008#contact"
// }
// ],
// "title": {
// "$t": "Joe Sample"
// },
// "link": [
// {
// "rel": "http://schemas.google.com/contacts/2008/rel#photo",
// "type": "image/*",
// "href": "https://www.googleapis.com/m8/feeds/photos/media/chilkat.support%40gmail.com/0"
// },
// {
// "rel": "self",
// "type": "application/atom+xml",
// "href": "https://www.googleapis.com/m8/feeds/contacts/chilkat.support%40gmail.com/full/0"
// },
// {
// "rel": "edit",
// "type": "application/atom+xml",
// "href": "https://www.googleapis.com/m8/feeds/contacts/chilkat.support%40gmail.com/full/0"
// }
// ],
// "gd$name": {
// "gd$fullName": {
// "$t": "Joe Sample"
// },
// "gd$givenName": {
// "$t": "Joe"
// },
// "gd$familyName": {
// "$t": "Sample"
// }
// },
// "gd$email": [
// {
// "address": "somebody@gmail.com",
// "primary": "true",
// "rel": "http://schemas.google.com/g/2005#other"
// }
// ]
// },
// ... more entries ...
//