Xojo Plugin
Send GMail using REST API

Demonstrates how to send an email using the GMail REST API.
Chilkat Xojo Plugin Downloads

Xojo Plugin
Dim success As Boolean
success = False

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

// Use the Chilkat Email API to create or load an email.
Dim email As New Chilkat.Email

// The From name/address don't need to be specified. 
// GMail will automatically use your Gmail address if the following 2 lines are omitted.
email.FromName = "My Name"
email.FromAddress = "my_account_name@gmail.com"

success = email.AddTo("John Smith","somebody@somewhere.com")
// To add more recipients, make additional calls to AddTo or AddCC, one per recipient...

email.Subject = "This is a test GMail email created using Chilkat."
email.Charset = "utf-8"
success = email.AddPlainTextAlternativeBody("This is a test")

// Create an HTML email body with an embedded image.
Dim cid As String
cid = email.AddRelatedFile("qa_data/jpg/starfish.jpg")
Dim sbHtml As New Chilkat.StringBuilder
success = sbHtml.Append("<html><body>This is a <b>test</b><br><img src=""cid:STARFISH_CID""/></body></html>")
Dim numReplacements As Int32
numReplacements = sbHtml.Replace("STARFISH_CID",cid)

success = email.AddHtmlAlternativeBody(sbHtml.GetAsString())

// OK.. we now have an HTML email with an embedded JPG image
// We'll need to get the full MIME of the email encoded to a base64url string.
Dim sbMime As New Chilkat.StringBuilder
success = email.GetMimeSb(sbMime)
success = sbMime.Encode("base64url","utf-8")

// The body of the HTTP request will be JSON..
Dim json As New Chilkat.JsonObject
success = json.UpdateSb("raw",sbMime)

// Send the email...
Dim http As New Chilkat.Http
http.AuthToken = "GMAIL-ACCESS-TOKEN"

Dim url As String
url = "https://www.googleapis.com/gmail/v1/users/me/messages/send"
Dim resp As New Chilkat.HttpResponse
success = http.HttpJson("POST",url,json,"application/json",resp)
If (success = False) Then
    System.DebugLog(http.LastErrorText)
    Return
End If

// A status code of 200 indicates success.
System.DebugLog("Response status code: " + Str(resp.StatusCode))
System.DebugLog("Response body:")
System.DebugLog(resp.BodyStr)

// The response body contains JSON.
// Use the online tool at Generate JSON Parsing Code
// to generate JSON parsing code.

// A sample successful JSON response:

// {
//  "id": "166f0d4ac39e50bf",
//  "threadId": "166f0d4ac39e50bf",
//  "labelIds": [
//   "SENT"
//  ]
// }