(Xojo Plugin) Secure FTP with Client Certificate

Chilkat FTP2 provides the ability to use a client certificate with secure FTP (implicit or explicit SSL/TLS). This example demonstrates how to load a certificate from a .pfx and use it as the client-side SSL cert. Note: Client-side certificates are only needed in situations where the server demands one.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim ftp As New Chilkat.Ftp2

ftp.Hostname = "ftp.***.com"
ftp.Port = 21
ftp.Username = "test"
ftp.Password = "test"

// This example will use explict TLS/SSL.
// Establish an explicit secure channel after connection
// on the standard FTP port 21.
ftp.AuthTls = True

// The Ssl property is for establishing an implicit SSL connection
// on port 990.  Because this example uses explicit SSL, it 
// should remain False.
ftp.Ssl = False

// Load a certificate from a .pfx
// A PFX may contain several certs, including the certificates
// in a chain of authority.
Dim certStore As New Chilkat.CertStore
Dim password As String
password = "***"
// Load the certs from a PFX into an in-memory certificate store:
Dim success As Boolean
success = certStore.LoadPfxFile("chilkat.pfx",password)
If (success <> True) Then
    System.DebugLog(certStore.LastErrorText)
    Return
End If

// Find the exact cert we'll use:
Dim cert As Chilkat.Cert
cert = certStore.FindCertBySubject("Chilkat Software, Inc.")
If (certStore.LastMethodSuccess = False) Then
    System.DebugLog("Certificate not found!")
    Return
End If

// Use this certificate for our secure (SSL/TLS) connection:
success = ftp.SetSslClientCert(cert)

// Connect and login to the FTP server.  The connection is 
// made secure because of the AuthTls setting.
success = ftp.Connect()
If (success <> True) Then
    System.DebugLog(ftp.LastErrorText)
    Return
Else
    // LastErrorText contains information even when
    // successful. This allows you to visually verify
    // that the secure connection actually occurred.
    System.DebugLog(ftp.LastErrorText)
End If

System.DebugLog("Secure FTP Channel Established!")

// Do whatever you're doing to do ...
// upload files, download files, etc...

// .....
// .....

success = ftp.Disconnect()