Xojo Plugin

Frame.io - Upload an Asset

See more Frame.io Examples

Upload an asset to Frame.io Xojo Plugin

Dim success As Boolean
success = False

// This example assumes the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim http As New Chilkat.Http

// Implements the following CURL command:

// curl --request POST \
//   --url https://api.frame.io/v2/assets/<ASSET_ID>/children \
//   --header 'authorization: Bearer <FRAME_IO_DEV_TOKEN>' \
//   --header 'content-type: application/json' \
//   --data '{"filesize":1570024 ,"filetype":"video/mp4","name":"rotating_earth","type":"file"}'

// Use the following online tool to generate HTTP code from a CURL command
// Convert a cURL Command to HTTP Source Code

// Use this online tool to generate code from sample JSON:
// Generate Code to Create JSON

// The following JSON is sent in the request body.

// {
//   "filesize": 1570024,
//   "filetype": "video/mp4",
//   "name": "rotating_earth",
//   "type": "file"
// }

Dim localFilePath As String
localFilePath = "qa_data/mp4/rotating_earth.mp4"
Dim fac As New Chilkat.FileAccess
Dim fileSize As Int32
fileSize = fac.FileSize(localFilePath)

Dim json As New Chilkat.JsonObject
success = json.UpdateInt("filesize",fileSize)
success = json.UpdateString("filetype","video/mp4")
success = json.UpdateString("name","rotating_earth7")
success = json.UpdateString("type","file")

http.SetRequestHeader "content-type","application/json"
// Adds the "Authorization: Bearer <FRAME_IO_DEV_TOKEN>" header.
http.AuthToken = "<FRAME_IO_DEV_TOKEN>"

// Uploading to asset ID: 039845e8-bffe-4d6b-88d3-c780bae06342
Dim resp As New Chilkat.HttpResponse
success = http.HttpJson("POST","https://api.frame.io/v2/assets/039845e8-bffe-4d6b-88d3-c780bae06342/children",json,"application/json",resp)
If (success = False) Then
    System.DebugLog(http.LastErrorText)
    Return
End If

Dim sbResponseBody As New Chilkat.StringBuilder
success = resp.GetBodySb(sbResponseBody)
Dim jResp As New Chilkat.JsonObject
success = jResp.LoadSb(sbResponseBody)
jResp.EmitCompact = False

System.DebugLog("Response Body:")
System.DebugLog(jResp.Emit())

Dim respStatusCode As Int32
respStatusCode = resp.StatusCode
System.DebugLog("Response Status Code = " + Str(respStatusCode))
If (respStatusCode >= 400) Then
    System.DebugLog("Response Header:")
    System.DebugLog(resp.Header)
    System.DebugLog("Failed.")
    Return
End If

// Upload in chunks to the pre-signed S3 upload URLs.
// There are ways to do this in parallel, but for simplicity we'll show how to upload
// one chunk after another.
Dim numChunks As Int32
numChunks = jResp.SizeOfArray("upload_urls")
Dim sizePerChunk As Int32
sizePerChunk = (fileSize + numChunks - 1) / numChunks

System.DebugLog("numChunks = " + Str(numChunks))
System.DebugLog("sizePerChunk = " + Str(sizePerChunk))

success = fac.OpenForRead(localFilePath)
If (success = False) Then
    System.DebugLog(fac.LastErrorText)
    Return
End If

Dim bd As New Chilkat.BinData
Dim httpForUpload As New Chilkat.Http

httpForUpload.SetRequestHeader "x-amz-acl","private"

Dim i As Int32
i = 0
While (i < numChunks)
    success = bd.Clear()
    success = fac.ReadBlockBd(i,sizePerChunk,bd)

    jResp.I = i
    Dim uploadUrl As String
    uploadUrl = jResp.StringOf("upload_urls[i]")

    // Send the chunk in a PUT:

    System.DebugLog("PUT chunk " + Str(i + 1))
    System.DebugLog("URL: " + uploadUrl)

    // PUT https://frameio-uploads-production.s3/etc/etc
    // Content-Type: video/mp4
    // x-amz-acl: private
    success = httpForUpload.HttpBd("PUT",uploadUrl,bd,"video/mp4",resp)
    If (success = False) Then
        System.DebugLog(httpForUpload.LastErrorText)
        Return
    End If

    System.DebugLog("response status: " + Str(resp.StatusCode))

    i = i + 1
Wend

fac.FileClose 

System.DebugLog("File uploaded.")