(Xojo Plugin) FatturaPA XML Invoice Sign+Encrypt to P7M

Demonstrates how to create a CAdES BES signed + encrypted invoice.xml.p7m for the Italian FatturaPA exchange system.

Note: This example requires Chilkat v9.5.0.75 or greater.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// Note: Requires Chilkat v9.5.0.75 or greater.

// This requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim crypt As New Chilkat.Crypt2

// Use a digital certificate and private key from a PFX file (.pfx or .p12).
Dim pfxPath As String
pfxPath = "qa_data/pfx/cert_test123.pfx"
Dim pfxPassword As String
pfxPassword = "test123"

Dim cert As New Chilkat.Cert
Dim success As Boolean
success = cert.LoadPfxFile(pfxPath,pfxPassword)
If (success <> True) Then
    System.DebugLog(cert.LastErrorText)
    Return
End If

// Provide the signing cert (with associated private key).
success = crypt.SetSigningCert(cert)
If (success <> True) Then
    System.DebugLog(crypt.LastErrorText)
    Return
End If

// Indicate that SHA-256 should be used.
crypt.HashAlgorithm = "sha256"

// Specify the signed attributes to be included.
// (This is what makes it CAdES-BES compliant.)
Dim jsonSignedAttrs As New Chilkat.JsonObject
success = jsonSignedAttrs.UpdateInt("contentType",1)
success = jsonSignedAttrs.UpdateInt("signingTime",1)
success = jsonSignedAttrs.UpdateInt("messageDigest",1)
success = jsonSignedAttrs.UpdateInt("signingCertificateV2",1)
crypt.SigningAttributes = jsonSignedAttrs.Emit()

Dim inFile As String
inFile = "qa_data/xml/IT01234567890_11002.xml"
Dim sigFile As String
sigFile = "qa_data/fatturapa/signed.p7m"

// Create the CAdES-BES signature, which contains the original data.
success = crypt.CreateP7M(inFile,sigFile)
If (success = False) Then
    System.DebugLog(crypt.LastErrorText)
    Return
End If

// Now we'll encrypt what was signed using FatturaPA's certificate (from a PEM file)
Dim encryptCert As New Chilkat.Cert
success = encryptCert.LoadFromFile("qa_data/certs/fatturapa_cert.pem")
If (success <> True) Then
    System.DebugLog(encryptCert.LastErrorText)
    Return
End If

crypt.CryptAlgorithm = "pki"

success = crypt.SetEncryptCert(encryptCert)
If (success <> True) Then
    System.DebugLog(crypt.LastErrorText)
    Return
End If

// Indicate the underlying bulk encryption algorithm to be used:
crypt.Pkcs7CryptAlg = "aes"
crypt.KeyLength = 128

// There's one last option that could be set.  If is the RSA encryption encryption/padding scheme. 
// By default, RSAES_PKCS1-V1_5 is used.  If desired, the OaepPadding property could be set to True to
// use RSAES_OAEP.  (We'll leave it set at the default value of False)
crypt.OaepPadding = False

// Everything is specified.  Encrypt the .p7m to create a new .p7m (which adds a layer of encryption around the opaque signature).
// The output is PKCS7 in binary DER format.
success = crypt.CkEncryptFile(sigFile,"qa_output/signed_and_encrypted.p7m")
If (success <> True) Then
    System.DebugLog(crypt.LastErrorText)
    Return
End If

System.DebugLog("Success.")