(Xojo Plugin) Dropbox Content Hash

Demonstrates how to compute the Dropbox content_hash of a file. (This is the "content_hash" found in the Dropbox FileMetadata object.

Note: This example requires Chilkat v9.5.0.79 or greater because it uses the fac.ReadBlockBd method.

For more information, see https://www.dropbox.com/developers/reference/content-hash

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim crypt As New Chilkat.Crypt2

// To calculate the content_hash of a file:
// Split the file into blocks of 4 MB (4,194,304 or 4 * 1024 * 1024 bytes). The last block (if any) may be smaller than 4 MB.
// Compute the hash of each block using SHA-256.
// Concatenate the hash of all blocks in the binary format to form a single binary string.
// Compute the hash of the concatenated string using SHA-256. Output the resulting hash in hexadecimal format.

crypt.HashAlgorithm = "sha256"
crypt.EncodingMode = "hex_lower"

// We're going to calculate the content_hash for the Milky Way JPG image linked here:  https://www.dropbox.com/developers/reference/content-hash

Dim fac As New Chilkat.FileAccess
Dim bd As New Chilkat.BinData
Dim bdHashes As New Chilkat.BinData

Dim success As Boolean
success = fac.OpenForRead("qa_data/jpg/milky-way-nasa.jpg")
If (success = False) Then
    System.DebugLog(fac.LastErrorText)
    Return
End If

Dim blockSize As Int32
blockSize = 4194304
Dim numBlocks As Int32
numBlocks = fac.GetNumBlocks(blockSize)

Dim i As Int32
i = 0
While (i < numBlocks)
    // Read the next 4MB block into bd.
    success = bd.Clear()
    success = fac.ReadBlockBd(i,blockSize,bd)

    Dim hashHex As String
    hashHex = crypt.HashBdENC(bd)
    System.DebugLog(Str(i) + ": " + hashHex)
    success = bdHashes.AppendEncoded(hashHex,"hex_lower")

    i = i + 1
Wend

fac.FileClose 

// Hash the concatenated SHA-256 hashes.
Dim content_hash As String
content_hash = crypt.HashBdENC(bdHashes)
System.DebugLog("content_hash = " + content_hash)