Xojo Plugin

Password_Digest = Base64 (SHA-1 ( nonce + created + SHA-1 (password) ) )

See more Encryption Examples

Demonstrates how to compute:

Password_Digest = Base64 (SHA-1 ( nonce + created + SHA-1 (password)))

Xojo Plugin

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim password As String
password = "secret"

Dim crypt As New Chilkat.Crypt2
crypt.HashAlgorithm = "SHA-1"
crypt.EncodingMode = "base64"

// Generate a 16-byte random nonce
Dim prng As New Chilkat.Prng
Dim bd As New Chilkat.BinData
Dim success As Boolean
success = prng.GenRandomBd(16,bd)

// Get the current date/time in a string with this format: 2010-06-08T07:26:50Z
Dim dt As New Chilkat.CkDateTime
success = dt.SetFromCurrentSystemTime()
Dim created As String
created = dt.GetAsTimestamp(False)
success = bd.AppendString(created,"utf-8")

// This example wishes to calculate a password digest like this:
// Password_Digest = Base64 ( SHA-1 ( nonce + created + SHA-1(password) ) )

// First SHA-1 digest the password...
Dim passwordSha1 As String
passwordSha1 = crypt.HashStringENC(password)
// Append the 20 binary bytes of the SHA1 hash to bd, which already contains the nonce and created date/time.
success = bd.AppendEncoded(passwordSha1,"base64")

Dim passwordDigest As String
passwordDigest = crypt.HashBdENC(bd)

System.DebugLog("Base64 password digest = " + passwordDigest)