Xojo Plugin

Box.com Streaming Upload File

See more Box Examples

Demonstrates how to upload a file to box.com, streaming the file directly from the filesystem.

Note: This example requires a fix that is included in Chilkat v9.5.0.70 and above.

Xojo Plugin

Dim success As Boolean
success = False

// This requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim rest As New Chilkat.Rest

//   Provide a previously obtained OAuth2 access token.
Dim oauth2 As New Chilkat.OAuth2
oauth2.AccessToken = "BOX_ACCESS_TOKEN"
success = rest.SetAuthOAuth2(oauth2)

// First, make the initial connection.
// A single REST object, once connected, can be used for many Box REST API calls.
// The auto-reconnect indicates that if the already-established HTTPS connection is closed,
// then it will be automatically re-established as needed.
Dim bAutoReconnect As Boolean
bAutoReconnect = True

// ----------------------------------------------------------------------
// IMPORTANT: Note that the domain is "upload.box.com", not "api.box.com"
// ----------------------------------------------------------------------
success = rest.Connect("upload.box.com",443,True,bAutoReconnect)
If (success <> True) Then
    System.DebugLog(rest.LastErrorText)
    Return
End If

// The request body uses the "multipart/form-data" format to transmit two "parts". 
// The first part is called "attributes" and contains a JSON object with information about the file, including the name of the file 
// and the ID of the parent folder. The second part contains the contents of the file. 
// (Note that the name of the second "part" is ignored.)

success = rest.AddHeader("Content-Type","multipart/form-data")

// Provide the content for each part of the request...

// First the JSON attributes.  Use "0" for the root folder.
//   {"name":"hedgehogs.jpg", "parent":{"id":"0"}}
Dim jsonAttr As New Chilkat.JsonObject
success = jsonAttr.UpdateString("name","hedgehogs.jpg")
success = jsonAttr.UpdateString("parent.id","0")

rest.PartSelector = "1"
success = rest.AddHeader("Content-Disposition","form-data; name=""attributes""; ")
success = rest.SetMultipartBodyString(jsonAttr.Emit())

// The upload will stream directly from a file.
rest.PartSelector = "2"
success = rest.AddHeader("Content-Disposition","form-data; name=""file""; filename=""hedgehogs.jpg""")
// "application/octet-stream" can be safely used for any type file..
success = rest.AddHeader("Content-Type","application/octet-stream")

// IMPORTANT: This example requires Chilkat v9.5.0.70 or later, for a fix that was made in
// multipart/streaming uploads. 
Dim fileStream As New Chilkat.Stream
fileStream.SourceFile = "qa_data/jpg/hedgehogs.jpg"
success = rest.SetMultipartBodyStream(fileStream)

// Restore the PartSelector to "0" (for safety, in case something else sends another request on this object)
rest.PartSelector = "0"

// Send the multipart/form-data request, which uploads the file by streaming directly from the filesystem.
Dim responseBody As String
responseBody = rest.FullRequestMultipart("POST","/api/2.0/files/content")
If (rest.LastMethodSuccess <> True) Then
    System.DebugLog(rest.LastErrorText)
    Return
End If

// A 201 is received for a successful upload
If (rest.ResponseStatusCode <> 201) Then
    System.DebugLog("Box.com upload failed.")
    System.DebugLog("Request header:")
    System.DebugLog(rest.LastRequestHeader)
    System.DebugLog("---")
    System.DebugLog("Response status code = " + Str(rest.ResponseStatusCode))
    System.DebugLog("Response body:")
    System.DebugLog(responseBody)
    Return
End If

System.DebugLog("File uploaded.")