Xojo Plugin

Blowfish OFB Output Feedback Mode Encryption

See more Encryption Examples

Demonstrates how to encrypt using Blowfish OFB (Output Feedback) mode. Xojo Plugin

// This example assumes the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim crypt As New Chilkat.Crypt2

// Use "blowfish2" to produce correct results that match published blowfish test vectors.
crypt.CryptAlgorithm = "blowfish2"
// Set the cipher mode to Output Feedback
crypt.CipherMode = "ofb"
crypt.KeyLength = 256

// EncodingMode specifies the encoding of the output for
// encryption, and the input for decryption.
// It may be "hex", "url", "base64", "quoted-printable", or many other choices.
crypt.EncodingMode = "hex"

// The block size of the blowfish algoirthm is 8 bytes, therefore the IV is 8 bytes.
Dim ivHex As String
ivHex = "0001020304050607"
crypt.SetEncodedIV ivHex,"hex"

// The secret key must equal the size of the key.  For
// 256-bit encryption, the binary secret key is 32 bytes.
Dim keyHex As String
keyHex = "603deb1015ca71be2b73aef0857d77811f352c073b6108d72d9810a30914dff4"
crypt.SetEncodedKey keyHex,"hex"

// Encrypt a string...
Dim encStr As String
encStr = crypt.EncryptStringENC("Emergencies have always been the pretext on which the safeguards of individual liberty have been eroded. -- Friedrich Hayek")
System.DebugLog(encStr)

Dim decrypt As New Chilkat.Crypt2
decrypt.CryptAlgorithm = "blowfish2"
decrypt.CipherMode = "ofb"
decrypt.KeyLength = 256
decrypt.EncodingMode = "hex"
decrypt.SetEncodedIV ivHex,"hex"
decrypt.SetEncodedKey keyHex,"hex"

// Now decrypt:
Dim decStr As String
decStr = decrypt.DecryptStringENC(encStr)
System.DebugLog(decStr)