(Xojo Plugin) Azure Storage: Upload Binary Data to Block Blob

Sample code to upload binary bytes to a block blob in Azure Cloud Storage. This creates the block blob, or replaces an existing block blob.

Note: The maximum size of a block blob created by uploading in a single step is 64MB. For larger files, the upload must be broken up into blocks. There is another Chilkat example for that..

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// Azure Blob Service Example: Upload binary bytes to a block blob.
// This creates a new block blob or replaces an existing one in its entirety.
// See also: https://msdn.microsoft.com/en-us/library/azure/dd179451.aspx

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim rest As New Chilkat.Rest

// Connect to the Azure Storage Blob Service
Dim bTls As Boolean
bTls = True
Dim port As Int32
port = 443
Dim bAutoReconnect As Boolean
bAutoReconnect = True
// In this example, the storage account name is "chilkat".
Dim success As Boolean
success = rest.Connect("chilkat.blob.core.windows.net",port,bTls,bAutoReconnect)
If (success <> True) Then
    System.DebugLog(rest.LastErrorText)
    Return
End If

// Provide Azure Cloud credentials for the REST call.
Dim azAuth As New Chilkat.AuthAzureStorage
azAuth.AccessKey = "AZURE_ACCESS_KEY"
// The account name used here should match the 1st part of the domain passed in the call to Connect (above).
azAuth.Account = "chilkat"
azAuth.Scheme = "SharedKey"
azAuth.Service = "Blob"
// This causes the "x-ms-version: 2021-08-06" header to be automatically added.
azAuth.XMsVersion = "2021-08-06"
success = rest.SetAuthAzureStorage(azAuth)

// Note: The application does not need to explicitly set the following
// headers: Content-Length, x-ms-date, Authorization.  These headers
// are automatically set by Chilkat.

// IMPORTANT: Make sure to set the x-ms-blob-type header:
success = rest.AddHeader("x-ms-blob-type","BlockBlob")

// For this example, we'll just load a JPG file into memory..
Dim binaryData As MemoryBlock
Dim fac As New Chilkat.FileAccess
binaryData = fac.ReadEntireFile("qa_data/jpg/starfish.jpg")

// Note: The maximum size of a block blob created by uploading in a single step is 64MB.  
// For larger files, the upload must be broken up into blocks.  There is another Chilkat example for that..
Dim responseStr As String
responseStr = rest.FullRequestBinary("PUT","/mycontainer/starfish.jpg",binaryData)
If (rest.LastMethodSuccess <> True) Then
    System.DebugLog(rest.LastErrorText)
    Return
End If

// When successful, the Azure Storage service will respond with a 201 response status code,
// with no response body.

If (rest.ResponseStatusCode <> 201) Then
    // Examine the request/response to see what happened.
    System.DebugLog("response status code = " + Str(rest.ResponseStatusCode))
    System.DebugLog("response status text = " + rest.ResponseStatusText)
    System.DebugLog("response header: " + rest.ResponseHeader)
    System.DebugLog("response body (if any): " + responseStr)
    System.DebugLog("---")
    System.DebugLog("LastRequestStartLine: " + rest.LastRequestStartLine)
    System.DebugLog("LastRequestHeader: " + rest.LastRequestHeader)
    Return
End If

System.DebugLog("Success.")