(Xojo Plugin) Azure Storage: List Blobs

Azure Storage Blob Service REST API: Sample code to fetch the list of blobs in the specified container.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// Azure Blob Service Example: List the blobs in a specified container.
// See also: https://msdn.microsoft.com/en-us/library/azure/dd135734.aspx

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim rest As New Chilkat.Rest

// Connect to the Azure Storage Blob Service
Dim bTls As Boolean
bTls = True
Dim port As Int32
port = 443
Dim bAutoReconnect As Boolean
bAutoReconnect = True
// In this example, the storage account name is "chilkat".
Dim success As Boolean
success = rest.Connect("chilkat.blob.core.windows.net",port,bTls,bAutoReconnect)
If (success <> True) Then
    System.DebugLog(rest.LastErrorText)
    Return
End If

// Provide Azure Cloud credentials for the REST call.
Dim azAuth As New Chilkat.AuthAzureStorage
azAuth.AccessKey = "AZURE_ACCESS_KEY"
// The account name used here should match the 1st part of the domain passed in the call to Connect (above).
azAuth.Account = "chilkat"
azAuth.Scheme = "SharedKey"
azAuth.Service = "Blob"
// This causes the "x-ms-version: 2020-08-04" header to be automatically added.
azAuth.XMsVersion = "2020-08-04"
success = rest.SetAuthAzureStorage(azAuth)

// Note: The application does not need to explicitly set the following
// headers: x-ms-date, Authorization.  These headers
// are automatically set by Chilkat.

// The expected success response is a 200 response status code with an XML response body.
// In this example, we are listing the blobs in the container named "mycontainer".
Dim responseStr As String
responseStr = rest.FullRequestNoBody("GET","/mycontainer?restype=container&comp=list")
If (rest.LastMethodSuccess <> True) Then
    System.DebugLog(rest.LastErrorText)
    Return
End If

// When successful, the Azure Storage service will respond with a 200 response status code,
// with an XML response body.

If (rest.ResponseStatusCode <> 200) Then
    // Examine the request/response to see what happened.
    System.DebugLog("response status code = " + Str(rest.ResponseStatusCode))
    System.DebugLog("response status text = " + rest.ResponseStatusText)
    System.DebugLog("response header: " + rest.ResponseHeader)
    System.DebugLog("response body (if any): " + responseStr)
    System.DebugLog("---")
    System.DebugLog("LastRequestStartLine: " + rest.LastRequestStartLine)
    System.DebugLog("LastRequestHeader: " + rest.LastRequestHeader)
    Return
End If

// Load the XML response for parsing.
// An example of the response XML is shown below.
Dim xml As New Chilkat.Xml
success = xml.LoadXml(responseStr)

System.DebugLog(xml.GetXml())

// Let's iterate over the blobs...

Dim lastMod As New Chilkat.CkDateTime

Dim numBlobs As Int32
numBlobs = xml.NumChildrenAt("Blobs")
Dim i As Int32
i = 0
While i < numBlobs
    System.DebugLog("---- Blob " + Str(i) + " ----")
    xml.I = i
    System.DebugLog("Name: " + xml.GetChildContent("Blobs|Blob[i]|Name"))
    System.DebugLog("Content-Length: " + xml.GetChildContent("Blobs|Blob[i]|Properties|Content-Length"))
    System.DebugLog("Content-Type: " + xml.GetChildContent("Blobs|Blob[i]|Properties|Content-Type"))
    System.DebugLog("Content-MD5: " + xml.GetChildContent("Blobs|Blob[i]|Properties|Content-MD5"))
    System.DebugLog("BlobType: " + xml.GetChildContent("Blobs|Blob[i]|Properties|BlobType"))
    System.DebugLog("LeaseStatus: " + xml.GetChildContent("Blobs|Blob[i]|Properties|LeaseStatus"))
    success = lastMod.SetFromRfc822(xml.GetChildContent("Blobs|Blob[i]|Properties|Last-Modified"))
    Dim dt As Chilkat.DtObj
    dt = lastMod.GetDtObj(True)
    System.DebugLog("Last-Modified YMD: " + Str(dt.Year) + "," + Str(dt.Month) + "," + Str(dt.Day))

    i = i + 1
Wend

System.DebugLog("-------------------------")

// Use the ChilkatPath method to get information for a specific blob:

// For example, let's say we want the Last-Modified date/time for
// the blob named "helloWorld.txt"
Dim lastModStr As String
lastModStr = xml.ChilkatPath("/C/Name,helloWorld.txt|..|Properties|Last-Modified|*")
System.DebugLog("helloWorld.txt Last-Modified: " + lastModStr)

System.DebugLog("Success.")

// <?xml version="1.0" encoding="utf-8" ?>
// <EnumerationResults ServiceEndpoint="https://chilkat.blob.core.windows.net/" ContainerName="test">
//     <Blobs>
//         <Blob>
//             <Name>hamletC.xml</Name>
//             <Properties>
//                 <Last-Modified>Mon, 02 May 2016 23:50:30 GMT</Last-Modified>
//                 <Etag>0x8D372E48B6D323A</Etag>
//                 <Content-Length>279658</Content-Length>
//                 <Content-Type>application/octet-stream</Content-Type>
//                 <Content-Encoding />
//                 <Content-Language />
//                 <Content-MD5>4E6prI9haw81xadSLeEj3Q==</Content-MD5>
//                 <Cache-Control />
//                 <Content-Disposition>attachment; filename="hamletC.xml"</Content-Disposition>
//                 <BlobType>BlockBlob</BlobType>
//                 <LeaseStatus>unlocked</LeaseStatus>
//                 <LeaseState>available</LeaseState>
//             </Properties>
//         </Blob>
//         <Blob>
//             <Name>helloWorld.txt</Name>
//             <Properties>
//                 <Last-Modified>Mon, 02 May 2016 15:21:55 GMT</Last-Modified>
//                 <Etag>0x8D3729D7EE38299</Etag>
//                 <Content-Length>12</Content-Length>
//                 <Content-Type>application/octet-stream</Content-Type>
//                 <Content-Encoding />
//                 <Content-Language />
//                 <Content-MD5>7Qdih1MuhjZehB6Sv8UNjA==</Content-MD5>
//                 <Cache-Control />
//                 <Content-Disposition>attachment; filename="helloWorld.txt"</Content-Disposition>
//                 <BlobType>BlockBlob</BlobType>
//                 <LeaseStatus>unlocked</LeaseStatus>
//                 <LeaseState>available</LeaseState>
//             </Properties>
//         </Blob>
//         <Blob>
//             <Name>thisIsATest.txt</Name>
//             <Properties>
//                 <Last-Modified>Tue, 03 May 2016 00:22:13 GMT</Last-Modified>
//                 <Etag>0x8D372E8F9B2A62E</Etag>
//                 <Content-Length>1600</Content-Length>
//                 <Content-Type>application/octet-stream</Content-Type>
//                 <Content-Encoding />
//                 <Content-Language />
//                 <Content-MD5>FhgUXYfePg2ItsraPmz0Xg==</Content-MD5>
//                 <Cache-Control />
//                 <Content-Disposition>attachment; filename="thisIsATest.txt"</Content-Disposition>
//                 <BlobType>BlockBlob</BlobType>
//                 <LeaseStatus>unlocked</LeaseStatus>
//                 <LeaseState>available</LeaseState>
//             </Properties>
//         </Blob>
//     </Blobs>
//     <NextMarker />
// </EnumerationResults>
//