Xojo Plugin

Azure Key Vault Find Certificate

See more Azure Key Vault Examples

Let's say you have the certificate locally, but not with the private key. You only have the certificate, such as in a .cer file, but not the .pfx. The purpose of this example is to show how to find the same certificate in Azure Key Vault, and return the Azure Key Vault's name for the certificate.

Note: This example requires Chilkat v9.5.0.96 or later.

Xojo Plugin

Dim success As Boolean
success = False

// This requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

// We have a .cer file locally, and we want to find this same certificate in Azure Key Vault
// because we'll need Azure Key Vault's name (and version) for the certificate if we are going to ask
// Key Vault to sign using the cert's private key.

Dim cert As New Chilkat.Cert
success = cert.LoadFromFile("qa_data/certs/myCert.cer")
If (success = False) Then
    System.DebugLog(cert.LastErrorText)
    Return
End If

// Let's the the SHA1 thumbprint for our cert in base64url format.  This is the "x5t" member that we'll 
// be seeking in the list of certificates returned from Azure Key Vault.
Dim bdThumbprint As New Chilkat.BinData
success = bdThumbprint.AppendEncoded(cert.Sha1Thumbprint,"hex")
Dim seek_x5t As String
seek_x5t = bdThumbprint.GetEncoded("base64url")
System.DebugLog("Seeking the cert with x5t = " + seek_x5t)

// Provide information needed for Chilkat to automatically get an OAuth2 access token as needed.
Dim json As New Chilkat.JsonObject
success = json.UpdateString("client_id","APP_ID")
success = json.UpdateString("client_secret","APP_PASSWORD")
success = json.UpdateString("resource","https://vault.azure.net")
success = json.UpdateString("token_endpoint","https://login.microsoftonline.com/TENANT_ID/oauth2/token")

Dim http As New Chilkat.Http

// Instead of providing an actual access token, we give Chilkat the information that allows it to 
// automatically fetch the access token using the OAuth2 client credentials flow.
http.AuthToken = json.Emit()

// Download JSON containing information about the certs in the Azure Key Vault.
// Replace VAULT_NAME with the name of your Azure Key Vault.
Dim sbResponse As New Chilkat.StringBuilder
success = http.QuickGetSb("https://VAULT_NAME.vault.azure.net/certificates?api-version=7.4",sbResponse)
If (success = False) Then

    Dim statusCode As Int32
    statusCode = http.LastStatus
    If (statusCode = 0) Then
        // We did not get a response from the server..
        System.DebugLog(http.LastErrorText)
    Else
        // We received a response, but it was an error.
        System.DebugLog("Error response status code: " + Str(statusCode))
        System.DebugLog("Error response:")
        System.DebugLog(sbResponse.GetAsString())
    End If

    Return
End If

Dim jsonResp As New Chilkat.JsonObject
success = jsonResp.LoadSb(sbResponse)
jsonResp.EmitCompact = False

// The JSON will contain an array of certs like this:

// {
//   "value": [
//     {
//       "id": "https://kvchilkat.vault.azure.net/certificates/BadSSL",
//       "x5t": "U04xLnb8Ww7BKkW9dD7P1cCHNDY",
//       "attributes": {
//         "enabled": true,
//         "nbf": 1674409014,
//         "exp": 1737481014,
//         "created": 1697294224,
//         "updated": 1697294224
//       },
//       "subject": ""
//     },
// ...
// ...

// Find the record having an "x5t" value equal to the one we're seeking.
Dim jsonRec As Chilkat.JsonObject
jsonRec = jsonResp.FindRecord("value","x5t",seek_x5t,True)
If (jsonResp.LastMethodSuccess = False) Then
    System.DebugLog("Did not find a matching certificate.")
Else
    System.DebugLog("Found the matching certificate.")
    // The id is a value such as https://kvchilkat.vault.azure.net/certificates/BadSSL
    System.DebugLog("id: " + jsonRec.StringOf("id"))

    // The name of the certificate is the last word after the final "/", such as "BadSSL"
    Dim sbId As New Chilkat.StringBuilder
    success = sbId.Append(jsonRec.StringOf("id"))
    Dim certName As String
    certName = sbId.GetAfterFinal("/",False)
    System.DebugLog("name: " + certName)

End If