|
(Xojo Plugin) Create CAdES p7m using Azure Key Vault to Sign in the Cloud
Demonstrates how to create a CAdES p7m, using Azure Key Vault. The signing of the hash happens in the Cloud on Azure Key Vault. Everything else regarding the creation of CAdES happens locally within Chilkat.
Note: This example requires Chilkat v9.5.0.96 or greater.
// This example assumes the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.
// Load the certificate used for signing. The certificate's private key is stored in
// the Azure Key Vault.
// However, we still need the certificate locally (without private key).
Dim cert As New Chilkat.Cert
Dim success As Boolean
success = cert.LoadFromFile("qa_data/certs/myCert.cer")
If (success = False) Then
System.DebugLog(cert.LastErrorText)
Return
End If
// Here's a screenshot of our certificate with private key on Azure Key Vault:
// To sign using the Azure Key Vault,
// add the following lines of code to specify your authentication credentials,
// and the name of the certificate w/ private key on the Azure server to be used.
Dim jsonAzure As New Chilkat.JsonObject
// Set the "service" equal to "azure_keyvault" to tell Chilkat to use Azure Key Vault for signing.
success = jsonAzure.UpdateString("service","azure_keyvault")
success = jsonAzure.UpdateString("client_id","APP_ID")
success = jsonAzure.UpdateString("client_secret","APP_PASSWORD")
success = jsonAzure.UpdateString("tenant_id","TENANT_ID")
// In the above screenshot, our vault name is "kvchilkat". You will use your vault name.
success = jsonAzure.UpdateString("vault_name","VAULT_NAME")
// In the above screenshot, our cert name is "ChilkatTest1". You will use your cert name.
success = jsonAzure.UpdateString("cert_name","CERT_NAME")
// In the above screenshot, our cert version is "63b94a23389546ecbc8eb6208a1bef37". You will use your cert version.
success = jsonAzure.UpdateString("cert_version","CERT_VERSION")
success = cert.SetCloudSigner(jsonAzure)
Dim crypt As New Chilkat.Crypt2
success = crypt.SetSigningCert(cert)
If (success = False) Then
System.DebugLog(crypt.LastErrorText)
Return
End If
// The CadesEnabled property applies to all methods that create PKCS7 signatures.
// To create a CAdES-BES signature, set this property equal to true.
crypt.CadesEnabled = True
crypt.HashAlgorithm = "sha256"
Dim signedAttrs As New Chilkat.JsonObject
success = signedAttrs.UpdateInt("contentType",1)
success = signedAttrs.UpdateInt("signingTime",1)
success = signedAttrs.UpdateInt("messageDigest",1)
success = signedAttrs.UpdateInt("signingCertificateV2",1)
crypt.SigningAttributes = signedAttrs.Emit()
// You can sign any type of file..
Dim inputXmlPath As String
inputXmlPath = "qa_data/e-Invoice.xml"
Dim outputP7mPath As String
outputP7mPath = "qa_output/signed.p7m"
// Create the CAdES-BES attached signature, which contains the original data.
// Chilkat will build the .p7m locally, but will (internally) use ARSS
// to do the RSA signing remotely.
success = crypt.CreateP7M(inputXmlPath,outputP7mPath)
If (success = False) Then
System.DebugLog(crypt.LastErrorText)
Return
End If
System.DebugLog("Success.")
|