(Xojo Plugin) Azure File Service: Upload Large File

Sample code to upload a large file to a directory in a share in the Azure File Service. A file is uploaded by first creating the file in the Azure share and then writing ranges of bytes to the file. Azure imposes a 4MB limit for each PUT to write a range. Files larger than 4MB need to be uploaded by making multiple "Put Range" calls. This example uploads a large file requiring multiple "Put Range" calls.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// Azure File Service Example: Upload a large file.  
// See:  https://docs.microsoft.com/en-us/rest/api/storageservices/create-share
// also see: https://docs.microsoft.com/en-us/rest/api/storageservices/put-range

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim rest As New Chilkat.Rest

// Connect to the Azure Storage Blob Service
Dim bTls As Boolean
bTls = True
Dim port As Int32
port = 443
Dim bAutoReconnect As Boolean
bAutoReconnect = True
// In this example, the storage account name is "chilkat".
Dim success As Boolean
success = rest.Connect("chilkat.file.core.windows.net",port,bTls,bAutoReconnect)
If (success <> True) Then
    System.DebugLog(rest.LastErrorText)
    Return
End If

// This example will upload a larger file.
Dim localFilePath As String
localFilePath = "qa_data/zips/somethingBig.zip"
Dim fac As New Chilkat.FileAccess
// Note: The FileSize method returns a signed 32-bit integer.  If the file is potentially larger than 2GB, call FileSizeStr instead to return
// the size of the file as a string, then convert to an integer value.
Dim szLocalFile As Int32
szLocalFile = fac.FileSize(localFilePath)
If (szLocalFile < 0) Then
    System.DebugLog(fac.LastErrorText)
    Return
End If

// Provide Azure Cloud credentials for the REST calls.
Dim azAuth As New Chilkat.AuthAzureStorage
azAuth.AccessKey = "AZURE_ACCESS_KEY"
// The account name used here should match the 1st part of the domain passed in the call to Connect (above).
azAuth.Account = "chilkat"
azAuth.Scheme = "SharedKey"
azAuth.Service = "File"
// This causes the "x-ms-version: 2020-08-04" header to be automatically added.
azAuth.XMsVersion = "2020-08-04"
success = rest.SetAuthAzureStorage(azAuth)

// Note: The application does not need to explicitly set the following
// headers: x-ms-date, Authorization.  These headers
// are automatically set by Chilkat.

// However, a few additional headers are required for the "Create File" operation:
success = rest.AddHeader("x-ms-type","file")

// This required header specifies the final size of the file (or the maximum size it can be).
Dim sbFileSize As New Chilkat.StringBuilder
success = sbFileSize.AppendInt(szLocalFile)
success = rest.AddHeader("x-ms-content-length",sbFileSize.GetAsString())

// Send a PUT request to create the file (or replace the file if it already exists).
// This will initialize the file in the Azure file storage.  To upload content, we'll need
// to do the "Put Range" operation one or more times.

// The following will create the file "somethingBig.zip" in the share "pip"
Dim responseStr As String
responseStr = rest.FullRequestNoBody("PUT","/pip/somethingBig.zip")
If (rest.LastMethodSuccess <> True) Then
    System.DebugLog(rest.LastErrorText)
    Return
End If

// When successful, the Azure File Service will respond with a 201 (Created) response status code,
// with no XML response body.  If an error response is returned, there will be an XML response body.

If (rest.ResponseStatusCode <> 201) Then
    // Examine the request/response to see what happened.
    System.DebugLog("response status code = " + Str(rest.ResponseStatusCode))
    System.DebugLog("response status text = " + rest.ResponseStatusText)
    System.DebugLog("response header: " + rest.ResponseHeader)
    System.DebugLog("response body (if any): " + responseStr)
    System.DebugLog("---")
    System.DebugLog("LastRequestStartLine: " + rest.LastRequestStartLine)
    System.DebugLog("LastRequestHeader: " + rest.LastRequestHeader)
    Return
End If

System.DebugLog("Successfully created somethingBig.zip")

// --------------------------------------------------------------------------------
// Upload the file data...

// Make sure the headers from the "Create File" operation are removed.
success = rest.ClearAllHeaders()

// The x-ms-write header is required for each "Put Range" request.
success = rest.AddHeader("x-ms-write","update")

Dim sbRange As New Chilkat.StringBuilder
Dim sbResponseBody As New Chilkat.StringBuilder
Dim bdFileData As New Chilkat.BinData

// Open the file.  We'll be reading and uploading in chunks..
success = fac.OpenForRead(localFilePath)
If (success <> True) Then
    System.DebugLog(fac.LastErrorText)
    Return
End If

Dim numBytesLeft As Int32
numBytesLeft = szLocalFile
Dim curIndex As Int32
curIndex = 0
While numBytesLeft > 0

    Dim chunkSize As Int32
    chunkSize = numBytesLeft
    // Azure allows for 4MB max chunks  (4 x 1024 x 1024 = 4194304)
    If (chunkSize > 4194304) Then
        chunkSize = 4194304
    End If

    // The only tricky part here is to correctly add the x-ms-range header.
    // It will be formatted like this:
    // x-ms-range: bytes=0-759623
    sbRange.Clear 
    success = sbRange.Append("bytes=")
    success = sbRange.AppendInt(curIndex)
    success = sbRange.Append("-")
    success = sbRange.AppendInt(curIndex + chunkSize - 1)

    // This replaces the header if it already exists..
    success = rest.AddHeader("x-ms-range",sbRange.GetAsString())

    // Read the next chunk from the local file.
    success = bdFileData.Clear()
    success = fac.FileReadBd(chunkSize,bdFileData)

    success = rest.FullRequestBd("PUT","/pip/somethingBig.zip?comp=range",bdFileData,sbResponseBody)
    If (success <> True) Then
        // This would indicate a failure where no response was received.
        System.DebugLog(rest.LastErrorText)
        Return
    End If

    // A 201 response indicates the chunk was uploaded.
    If (rest.ResponseStatusCode <> 201) Then
        // Examine the request/response to see what happened.
        System.DebugLog("response status code = " + Str(rest.ResponseStatusCode))
        System.DebugLog("response status text = " + rest.ResponseStatusText)
        System.DebugLog("response header: " + rest.ResponseHeader)
        System.DebugLog("response body (if any): " + responseStr)
        System.DebugLog("---")
        System.DebugLog("LastRequestStartLine: " + rest.LastRequestStartLine)
        System.DebugLog("LastRequestHeader: " + rest.LastRequestHeader)
        Return
    End If

    System.DebugLog("Uploaded chunk from " + Str(curIndex) + " to " + Str(curIndex + chunkSize - 1))

    curIndex = curIndex + chunkSize
    numBytesLeft = numBytesLeft - chunkSize
Wend

fac.FileClose 

System.DebugLog("success.")