(Xojo Plugin) Cancel Async Task if not Completed after a Max Time

Demonstrates how to wait a maximum amount of time for an asynchronous task to completed. If not completed in the allotted amount of time, the task is cancelled.

Chilkat Xojo Plugin Download Xojo Plugin for Windows, Linux, Mac OS X, and ARM, ARM64

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim success As Boolean
Dim http As New Chilkat.Http

// Set some timeouts, in seconds:
http.ConnectTimeout = 15
http.ReadTimeout = 15

// Wait a max time of 2 seconds for the task.
// In this example, it's an unreasonably small amount of time,
// which means the task will get cancelled.
Dim waitMaxMs As Int32
waitMaxMs = 2000

// We're just going to download for 2 seconds and then cancel.
// Substitute your own URL with a large enough file for testing..
Dim downloadUrl As String
downloadUrl = "http://download.mono-project.com/archive/4.6.1/windows-installer/mono-4.6.1.5-gtksharp-2.12.38-win32-0.msi"

Dim task As Chilkat.Task
task = http.DownloadAsync(downloadUrl,"qa_output/mono.msi")
success = task.Run()

// Wait a maximum of waitMaxMs for the task (i.e. the HTTP download) to complete.
// The Wait method returns when the task has been canceled, aborted, or completed, or when the max allotted time has passed.
success = task.Wait(waitMaxMs)

// At this point, the download may or may not have completed.  
// Rather than checking the Task status, we can call task.Cancel because
// if the Task is no longer running (because it already completed, was canceled or aborted), then the 
// call to Cancel is a NO-OP (meaning it does nothing and the Task's status is unaffected).
// Also, task.Cancel returns True if the task was in the "queued" or "running" state and was canceled or aborted. 
// The method returns False if the task has any other status.
Dim wasCanceled As Boolean
wasCanceled = task.Cancel()
If (wasCanceled = True) Then
    System.DebugLog("The HTTP download took too long and was canceled.")
Else
    // Find out what happened.
    If (task.StatusInt = 7) Then
        // The task completed, which means the background thread's call to Download completed
        // with success or failure.  Find out which...
        success = task.GetResultBool()
        If (success = True) Then
            System.DebugLog("Download successful!")
        Else
            System.DebugLog("Download failed prior to waitMaxMs...")
            System.DebugLog(task.ResultErrorText)
        End If

    Else
        // The task must've been canceled or aborted by some other means..
        System.DebugLog("Task did not complete.  Final status: " + task.Status)
    End If

End If