Xojo Plugin

Async Methods Returning an String

See more Async Examples

Demonstrates how to call an asynchronous method that returns a string. This example sends an HTTPS GET request to a URL and gets the HTML response. Xojo Plugin

Dim success As Boolean
success = False

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim http As New Chilkat.Http

Dim task As Chilkat.Task
task = http.QuickGetStrAsync("https://www.chilkatsoft.com/helloWorld.html")
If (http.LastMethodSuccess = False) Then
    System.DebugLog(http.LastErrorText)
    Return
End If

// Start the background task.
success = task.Run()
If (Not success) Then
    System.DebugLog(task.LastErrorText)

    Return
End If

// The application is now free to do anything else

// For this example, we'll simply sleep and periodically
// check to see if the HTTPS GET if finished.
While task.Finished <> True
    // Sleep 100 ms.
    task.SleepMs 100
Wend

// A finished task could be one that was canceled, aborted, or truly finished.  

// If the task was "canceled", it was canceled prior to actually starting.  This could
// happen if the task was canceled while waiting in a thread pool queue to be scheduled by Chilkat's
// background thread pool scheduler.  

// If the task was "aborted", it indicates that it was canceled while running in a background thread.  
// The ResultErrorText will likely indicate that the task was aborted.

// If the task "completed", then it ran to completion, but the actual success/failure of the method
// is determined by the result obtained via a GetResult* method.  (A "completed" task will
// have a StatusInt equal to 7.   If the task finished, but was not completed, then it must've
// been aborted or canceled:
If (task.StatusInt <> 7) Then
    System.DebugLog("Task did not complete.")
    System.DebugLog("task status: " + task.Status)

    Return
End If

// The QuickGetStr method returns a string.  Therefore, after the task is finished,
// we can get the string result by calling GetResultString.  This is the return value had
// we called QuickGetStr synchronously.
Dim html As String
html = task.GetResultString()

System.DebugLog(html)