Xojo Plugin Requires Chilkat v11.5.0+

Create CAdES (p7m) Signature using ARSS (Aruba Remote Signing Service)

See more Signing in the Cloud Examples

Demonstrates creating a CAdES (p7m) signature using the Aruba Remote Signing Service. Xojo Plugin

Dim success As Boolean
success = False

//  This example assumes the Chilkat API to have been previously unlocked.
//  See Global Unlock Sample for sample code.

//  Load the certificate used for signing.  The certificate's private key is stored on 
//  the Aruba.it server and the signing will happen remotely using the
//  ARSS (Aruba Remote Signing Service).
//  However, we still need the certificate locally (without private key).
Dim cert As New Chilkat.Cert
success = cert.LoadFromFile("qa_data/certs/myCert.cer")
If (success = False) Then
    System.DebugLog(cert.LastErrorText)
    Return
End If

//  To sign using the Aruba Remote Signing Service, 
//  add the following lines of code to specify your authentication credentials,
//  and the ID of the certificate w/ private key on the server to be used.
Dim jsonArss As New Chilkat.JsonObject

//  Set the "service" equal to "ARSS" to tell Chilkat to use ARSS for signing.
success = jsonArss.UpdateString("service","ARSS")
//  Specify the certificate ID, such as "AS0"
//  This certificate should match the certificate loaded in the above code.
success = jsonArss.UpdateString("certID","YOUR_ARSS_CERT_ID")
success = jsonArss.UpdateString("otpPwd","YOUR_OTP_PWD")

//  Specifies the OTP authentication environment.
//  
//  Common values are:
//    "demoprod" - Demo/Test environment
//    "prod"     - Production environment
//  
//  This value is sent to the ARSS service and determines how the OTP
//  authentication is validated.  The correct value depends on the type
//  of Aruba account and environment that has been provisioned.
//  
//  If signing fails with an authentication-related error, verify that
//  the typeOtpAuth value matches the environment associated with the
//  ARSS account credentials being used.
success = jsonArss.UpdateString("typeOtpAuth","demoprod")

success = jsonArss.UpdateString("user","YOUR_ARSS_USERNAME")
success = jsonArss.UpdateString("userPWD","YOUR_ARSS_PASSWORD")

//  The "endpoint" can be specified starting in Chilkat v11.5.0
success = jsonArss.UpdateString("endpoint","https://app1.firma-remota.it/ArubaSignerService/webresources/signerservice")

success = cert.SetCloudSigner(jsonArss)

Dim crypt As New Chilkat.Crypt2

success = crypt.SetSigningCert(cert)
If (success = False) Then
    System.DebugLog(crypt.LastErrorText)
    Return
End If

//  The CadesEnabled property applies to all methods that create PKCS7 signatures. 
//  To create a CAdES-BES signature, set this property equal to true.
crypt.CadesEnabled = True

crypt.HashAlgorithm = "sha256"

Dim signedAttrs As New Chilkat.JsonObject
success = signedAttrs.UpdateInt("contentType",1)
success = signedAttrs.UpdateInt("signingTime",1)
success = signedAttrs.UpdateInt("messageDigest",1)
success = signedAttrs.UpdateInt("signingCertificateV2",1)
crypt.SigningAttributes = signedAttrs.Emit()

//  You can sign any type of file..
Dim inputXmlPath As String
inputXmlPath = "qa_data/e-Invoice.xml"
Dim outputP7mPath As String
outputP7mPath = "qa_output/signed.p7m"

//  Create the CAdES-BES attached signature, which contains the original data.
//  Chilkat will build the .p7m locally, but will (internally) use ARSS
//  to do the RSA signing remotely.
success = crypt.CreateP7M(inputXmlPath,outputP7mPath)
If (success = False) Then
    System.DebugLog(crypt.LastErrorText)
    Return
End If

System.DebugLog("Success.")