Xojo Plugin

Get ETK Public Key (api-acpt.ehealth.fgov.be)

See more Belgian eHealth Platform Examples

The following URL returns JSON, which contains a PKCS7 signed data:

https://api-acpt.ehealth.fgov.be/etee/v1/etks?identifier=12345678901&type=SSIN

This example extracts the signed data, validates it, and then extracts the public key from the certificate (obtained from signed content in the PKCS7)

Note: The URL above uses "12345678901" which is not valid. You should replace it with a valid number.

Xojo Plugin

Dim success As Boolean
success = False

// This example requires the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim http As New Chilkat.Http

Dim jsonStr As String
jsonStr = http.QuickGetStr("https://api-acpt.ehealth.fgov.be/etee/v1/etks?identifier=12345678901&type=SSIN")
If (http.LastMethodSuccess = False) Then
    System.DebugLog(http.LastErrorText)
    Return
End If

System.DebugLog(jsonStr)

// The JSON contains something like this:

// [
//     {
//         "key": {
//             "applicationIdentifier": "",
//             "ssin": "12345678901"
//         },
//         "value": "MIAGCSq....AAAAAAAA=="
//     }
// ]

// Note: The above is a JSON array (not a JSON object)
// It should be loaded into a Chilkat JSON array.
Dim jarr As New Chilkat.JsonArray
success = jarr.Load(jsonStr)
If (success = False) Then
    System.DebugLog("Failed to load JSON.")
    Return
End If

Dim json As Chilkat.JsonObject
json = jarr.ObjectAt(0)
Dim bdPkcs7 As New Chilkat.BinData
success = bdPkcs7.AppendEncoded(json.StringOf("value"),"base64")

// Let's verify the PKCS7, and then examine the signing cert,
// and get the signing cert's public key.
Dim crypt As New Chilkat.Crypt2

// Validate the signedData PKCS7, and replace the contents of bdPkcs7 with the extracted signed content.
success = crypt.OpaqueVerifyBd(bdPkcs7)
If (success = False) Then
    System.DebugLog(crypt.LastErrorText)
    Return
End If

// The signed content is the DER of a certificate.
// In other words, bdPkcs7 now contains a certificate.
Dim cert As New Chilkat.Cert
success = cert.LoadFromBd(bdPkcs7)
If (success = False) Then
    System.DebugLog(cert.LastErrorText)
    Return
End If

// Show some certificate information:
System.DebugLog("Subject: " + cert.SubjectDN)
System.DebugLog("Serial: " + cert.SerialNumber)
System.DebugLog("Issuer: " + cert.IssuerDN)

// Let's get the cert's public key...
Dim pubKey As New Chilkat.PublicKey
success = cert.GetPublicKey(pubKey)

// OK, you now have the public key and can do whatever is needed..
System.DebugLog(pubKey.KeyType)
System.DebugLog(Str(pubKey.KeySize))