Xojo Plugin

Prove Stateful Multi-Turn Conversation

See more AI Examples

This example is to prove that the 2nd request in a conversation is part of a stateful multi-turn conversation. The 2nd request asks for information provided in the 1st request. Xojo Plugin

Dim success As Boolean
success = False

// This example assumes the Chilkat API to have been previously unlocked.
// See Global Unlock Sample for sample code.

Dim ai As New Chilkat.Ai

// The provider can be "openai", "google", "claude", "deepseek", "xai", or "perplexity".
// Support for additional providers will be added in future versions of Chilkat.
ai.Provider = "google"

// Use your provider's API key.
ai.ApiKey = "MY_API_KEY"

// Choose a model.
ai.Model = "gemini-2.5-flash"

// Create a new conversation to be maintained locally in memory.
// If the conversation is the first to be created, it is also automatically selected.
Dim systemMsg As String
systemMsg = "You are a helpful assistant"
Dim developerMsg As String
developerMsg = ""
Dim conversationName As String
conversationName = "test_conversation"
success = ai.NewConvo(conversationName,systemMsg,developerMsg)

// -------------------------------------------------------------------------------------------
// Our first request will establish a secret that we'll ask for in the 2nd request.
// Add a text input.
success = ai.InputAddText("Please remember this: The word I'll ask for later is BlubberFish.  What's the word?")

// Ask the AI for text output.
success = ai.Ask("text")
If (success = False) Then
    System.DebugLog(ai.LastErrorText)
    Return
End If

// Note: The inputs accumulated through one or more calls to Input* methods are cleared when the Ask method returns with success.

// Get the text response.
Dim sbResponse As New Chilkat.StringBuilder
success = ai.GetOutputTextSb(sbResponse)
System.DebugLog(sbResponse.GetAsString())
System.DebugLog("----")

// Sample output:

// The word is **BlubberFish**.

// -------------------------------------------------------------------------------------------
// Let's ask for the word. If this is a stateful conversation, the AI should respond correctly.
success = ai.InputAddText("OK, I'm going to ask you again, what's the word?")
success = ai.Ask("text")
If (success = False) Then
    System.DebugLog(ai.LastErrorText)
    Return
End If

// Get the text response.
sbResponse.Clear 
success = ai.GetOutputTextSb(sbResponse)
System.DebugLog(sbResponse.GetAsString())

// Sample output:

// The word is **BlubberFish**.

// -------------------------------------------------------------------------------------------
// Look at the conversation so far...
// 
Dim json As New Chilkat.JsonObject
success = ai.ExportConvo(conversationName,json)
json.EmitCompact = False
System.DebugLog(json.Emit())

// Note: The conversation transcript format exported and imported by Chilkat is always the OpenAI format,
// regardless of the AI provider.  (Chilkat translates the format from OpenAI to whatever is needed by the actual AI provider being used.)

// {
//   "input": [
//     {
//       "role": "system",
//       "content": [
//         {
//           "type": "input_text",
//           "text": "You are a helpful assistant"
//         }
//       ]
//     },
//     {
//       "role": "user",
//       "content": [
//         {
//           "type": "input_text",
//           "text": "Please remember this: The word I'll ask for later is BlubberFish.  What's the word?"
//         }
//       ]
//     },
//     {
//       "role": "assistant",
//       "content": [
//         {
//           "type": "output_text",
//           "text": "The word is **BlubberFish**."
//         }
//       ]
//     },
//     {
//       "role": "user",
//       "content": [
//         {
//           "type": "input_text",
//           "text": "OK, I'm going to ask you again, what's the word?"
//         }
//       ]
//     },
//     {
//       "role": "assistant",
//       "content": [
//         {
//           "type": "output_text",
//           "text": "The word is **BlubberFish**."
//         }
//       ]
//     }
//   ]
// }

// -------------------------------------------------------------------------------------------
// If we unselect the conversation, so that no conversation is selected,
// then the same query results in the AI not knowing the word.

ai.SelectedConvo = ""

success = ai.InputAddText("OK, I'm going to ask you again, what's the word?")
success = ai.Ask("text")
If (success = False) Then
    System.DebugLog(ai.LastErrorText)
    Return
End If

// Get the text response.
sbResponse.Clear 
success = ai.GetOutputTextSb(sbResponse)
System.DebugLog(sbResponse.GetAsString())

// Sample output:

// I apologize, but I don't have the context of our previous interaction or what "the word" you're referring to might be.
// Could you please remind me or provide the clue again? I'm ready to help you figure it out!