Sample code for 30+ languages & platforms
Xojo Plugin

X.com OAuth 2.0 Authorization Code with PKCE

See more X Examples

Demonstrates how to get an X.com OAuth2 access token from a desktop application or script.

Chilkat Xojo Plugin Downloads

Download Chilkat for Xojo Plugin
Xojo Plugin 
Dim success As Boolean
success = False

// For more information about the OAuth2, see OAuth 2.0 Authorization Flow

Dim oauth2 As New Chilkat.OAuth2

// The port should match the Authorized Redirect URL in your X.com app, 
// which would look like "http://127.0.0.1:3017/"
// See the screenshot below of the App Settings in the X Developer Portal
oauth2.LocalHost = "127.0.0.1"
oauth2.ListenPort = 3017

oauth2.AuthorizationEndpoint = "https://x.com/i/oauth2/authorize"
oauth2.TokenEndpoint = "https://api.x.com/2/oauth2/token"

// Replace this with your actual X.com OAuth2 Client ID and Client Secret
oauth2.ClientId = "OAUTH2_CLIENT_ID"
oauth2.ClientSecret = "OAUTH2_CLIENT_SECRET"

// This is for Require Proof Key for Code Exchange (PKCE)
// See OAuth2 PKCE Explained
oauth2.CodeChallenge = True
oauth2.CodeChallengeMethod = "S256"

// Space separated scopes...
oauth2.Scope = "tweet.read tweet.write users.read follows.read follows.write offline.access like.read like.write block.read block.write"

// Begin the OAuth2 Authorization code flow.  This returns a URL that should be loaded in a browser.
Dim url As String
url = oauth2.StartAuth()
If (oauth2.LastMethodSuccess <> True) Then
    System.DebugLog(oauth2.LastErrorText)
    Return
End If

System.DebugLog("url = " + url)

// Launch the default browser on the system and navigate to the url.
// The LaunchBrowser method was added in Chilkat v10.1.2.
success = oauth2.LaunchBrowser(url)
If (success = False) Then
    System.DebugLog(oauth2.LastErrorText)
    Return
End If

// Wait for the user to approve or deny authorization in the browser.
Dim numMsWaited As Int32
numMsWaited = 0
While (numMsWaited < 10000) And (oauth2.AuthFlowState < 3)
    oauth2.SleepMs 100
    numMsWaited = numMsWaited + 100
Wend

// If the browser does not respond within the specified time, AuthFlowState will be:
// 
// 1: Waiting for Redirect - The OAuth2 background thread is waiting for the browser's redirect request.
// 2: Waiting for Final Response - The thread is awaiting the final access token response.
// In either case, cancel the background task initiated by StartAuth.

If (oauth2.AuthFlowState < 3) Then
    success = oauth2.Cancel()
    System.DebugLog("No response from the browser!")
    Return
End If

// Check AuthFlowState to determine if authorization was granted, denied, or failed:
// 
// 3: Success - OAuth2 flow completed, the background thread exited, and the successful response is in AccessTokenResponse.
// 4: Access Denied - OAuth2 flow completed, the background thread exited, and the error response is in AccessTokenResponse.
// 5: Failure - OAuth2 flow failed before completion, the background thread exited, and error details are in FailureInfo.

If (oauth2.AuthFlowState = 5) Then
    System.DebugLog("OAuth2 failed to complete.")
    System.DebugLog(oauth2.FailureInfo)
    Return
End If

If (oauth2.AuthFlowState = 4) Then
    System.DebugLog("OAuth2 authorization was denied.")
    System.DebugLog(oauth2.AccessTokenResponse)
    Return
End If

If (oauth2.AuthFlowState <> 3) Then
    System.DebugLog("Unexpected AuthFlowState:" + Str(oauth2.AuthFlowState))
    Return
End If

System.DebugLog("OAuth2 authorization granted!")

Dim json As New Chilkat.JsonObject
success = json.Load(oauth2.AccessTokenResponse)
json.EmitCompact = False

// If an "expires_on" member does not exist, then add the JSON member by
// getting the current system date/time and adding the "expires_in" seconds.
// This way we'll know when the token expires.
If (json.HasMember("expires_on") = False) Then
    Dim dtExpire As New Chilkat.CkDateTime
    success = dtExpire.SetFromCurrentSystemTime()
    success = dtExpire.AddSeconds(json.IntOf("expires_in"))
    success = json.AppendString("expires_on",dtExpire.GetAsUnixTimeStr(False))
End If

System.DebugLog("Access Token Response = " + json.Emit())

// A sample access token response:

// {
//   "token_type": "bearer",
//   "expires_in": 7200,
//   "access_token": "VmNDLVZiYUZwejY5Mkx3RblFTmo3ek1leTRGclMuZFVOUTVUTWpNbVZKb1N5OjE3NDAxNjk4MDVxNTE6MToxOaF0OjE",
//   "scope": "block.read follows.read offline.access tweet.write block.write like.write like.read users.read tweet.read follows.write",
//   "refresh_token": "eThOWVVFSTRqdVp3QTFndGsxM2ZGZmFyNWVrU0phM1JKbGdrbGNWRGJzb1loOjE3NDAwMjk4MDUxNTI6MTowOnJ0OjE"
// }

System.DebugLog("Access Token = " + oauth2.AccessToken)

System.DebugLog("Refresh Token = " + oauth2.RefreshToken)

// Save the JSON access token response to a file for subsequent use..
success = json.WriteFile("qa_data/tokens/x.json")

// image