VBScript

Download a Zip from a URL and OpenBd. (No .zip file is created)

See more Zip Examples

Demonstrates how to download a .zip from a URL, opens the Zip, and gets the contents of a file. No file is ever written. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")

set bd = CreateObject("Chilkat.BinData")

' This URL is valid and can be tested...
success = http.QuickGetBd("https://chilkatdownload.com/example_data/hamlet.zip",bd)
If (http.LastMethodSuccess = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

set zip = CreateObject("Chilkat.Zip")

' Open the zip from the bytes contained in bd.
success = zip.OpenBd(bd)
If (success = 0) Then
    outFile.WriteLine(zip.LastErrorText)
    WScript.Quit
End If

' Get the entry for the file we want..
set entry = CreateObject("Chilkat.ZipEntry")
success = zip.EntryOf("hamlet.xml",entry)
If (success = 0) Then
    outFile.WriteLine(zip.LastErrorText)
    WScript.Quit
End If

' Convert all line endings to CRLF (if needed)
lineEndingBehavior = 2
xmlStr = entry.UnzipToString(lineEndingBehavior,"utf-8")
If (entry.LastMethodSuccess = 0) Then
    outFile.WriteLine(entry.LastErrorText)
    WScript.Quit
End If

' The XML in this case is about 274K, so let's just examine the last 20 lines...
set sb = CreateObject("Chilkat.StringBuilder")
success = sb.Append(xmlStr)

outFile.WriteLine(sb.LastNLines(20,1))

outFile.Close