VBScript Requires Chilkat v11.0.0+

Modify Name of File Stored within Zip when Creating a .zip

See more Zip Examples

Demonstrates how to create a zip where the filename within the .zip is different than the filename that was added from the filesystem. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  This example requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

set zip = CreateObject("Chilkat.Zip")

'  Intialize the zip object by calling NewZip.
success = zip.NewZip("myZip.zip")

'  Add a reference to a file on disk to the zip object.
'  (When appending files to a zip, the files are not actually
'  read into memory.  References to the file(s) are added.
'  When WriteZip is called, the referenced files are streamed in
'  and compressed to the .zip.)
saveExtraPath = 0
success = zip.AddFile("/temp/a/hamlet.xml",saveExtraPath)
If (success = 0) Then
    outFile.WriteLine(zip.LastErrorText)
    WScript.Quit
End If

'  The zip object references a single file.
'  Retrieve the entry object...
set entry = CreateObject("Chilkat.ZipEntry")
success = zip.EntryAt(0,entry)

'  Set the entry's filename to anything you want:
entry.FileName = "somethingElse.xml"

'  Note: Internally, the zip component retains the name of
'  the file referenced.  The current setting of the zip entry's
'  FileName property is stored in the .zip when writing.

'  The zip written here will contain somethingElse.xml
success = zip.WriteZipAndClose()
If (success <> 1) Then
    outFile.WriteLine(zip.LastErrorText)
Else
    outFile.WriteLine("Zip created!")
End If


outFile.Close