VBScript

Create a WinZip/7-Zip compatible AES Encrypted Zip

See more Zip Examples

Creates a WinZip compatible AES-encrypted .zip archive VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set zip = CreateObject("Chilkat.Zip")

success = zip.NewZip("/myZipDir/aes.zip")
If (success <> 1) Then
    outFile.WriteLine(zip.LastErrorText)
    WScript.Quit
End If

' Set properties to indicate that the Zip should be
' AES encrypted.

' A value of 4 indicates WinZip compatible AES encryption.
zip.Encryption = 4

' Key length can be 128, 192, or 256 bits.
zip.EncryptKeyLength = 128

' Set the password for AES encryption:
zip.EncryptPassword = "myPassword"

' Add a directory tree to be zipped.  (The files
' are not compressed at this point -- only references
' to the files and directories are added to the zip object.)
recurse = 1
success = zip.AppendFiles("c:/temp/a/*",recurse)
If (success <> 1) Then
    outFile.WriteLine(zip.LastErrorText)
    WScript.Quit
End If

' Create the encrypted zip ("/myZipDir/aes.zip")
' The path of the zip is what was originally passed
' to the NewZip method (above).  
success = zip.WriteZipAndClose()
If (success <> 1) Then
    outFile.WriteLine(zip.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Created AES Encrypted Zip.")

outFile.Close