VBScript

Creates an AES Encrypted Zip with One File Unencrypted

See more Zip Examples

Demonstrates how to create an AES encrypted zip, but also containing one file that is not encrypted. The way we do it is to first create an AES encrypted zip in the usual way, and then we append an unecrypted file to it. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set zip = CreateObject("Chilkat.Zip")

success = zip.NewZip("qa_output/aes_with_one_unencrypted.zip")
If (success = 0) Then
    outFile.WriteLine(zip.LastErrorText)
    WScript.Quit
End If

' Set properties to indicate that the Zip should be
' AES encrypted.

' A value of 4 indicates WinZip compatible AES encryption.
zip.Encryption = 4

' Key length can be 128, 192, or 256 bits.
zip.EncryptKeyLength = 128

' Set the password for AES encryption:
zip.EncryptPassword = "myPassword"

' Exclude the file helloWorld.txt
' This file will be added unencrypted to the .zip
set saExclusions = CreateObject("Chilkat.StringArray")
success = saExclusions.Append("helloWorld.txt")
zip.SetExclusions saExclusions

zip.VerboseLogging = 1

' Add a directory tree to be zipped.
recurse = 1
' Append from a directory relative to our current working directory.
zip.AppendFromDir = "qa_data/filesToZip"
success = zip.AppendFiles("*",recurse)
If (success = 0) Then
    outFile.WriteLine(zip.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(zip.LastErrorText)

' Writes qa_output/aes_with_one_unencrypted.zip
success = zip.WriteZipAndClose()
If (success = 0) Then
    outFile.WriteLine(zip.LastErrorText)
    WScript.Quit
End If

' ----------------------------------------------
' At this point, we have an encrypted .zip with all 
' files except for helloWorld.txt.
' We'll add helloWorld.txt (unencrypted) to the .zip we just created.

' The NewZip method only initializes the Zip object -- it does
' not create or write a .zip file.

success = zip.NewZip("notUsed.zip")
If (success = 0) Then
    outFile.WriteLine(zip.LastErrorText)
    WScript.Quit
End If

saExclusions.Clear 
zip.SetExclusions saExclusions

' No encryption.
zip.Encryption = 0

zip.AppendFromDir = "qa_data/filesToZip"

' Add a reference to a file.  This is the file that will
' be added to a already-existing .zip.  
saveExtraPath = 0
success = zip.AddFile("helloWorld.txt",saveExtraPath)
If (success = 0) Then
    outFile.WriteLine(zip.LastErrorText)
    WScript.Quit
End If

' Appends the contents of the zip object to the preExisting.zip
' zip archive.  preExisting.zip is opened, and the files
' referenced by this zip object are streamed in, compressed,
' and appended to the end of the archive.
success = zip.QuickAppend("qa_output/aes_with_one_unencrypted.zip")
If (success = 0) Then
    outFile.WriteLine(zip.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success!")

outFile.Close