(VBScript) ZATCA QR Code TLV Encoding and ECDSA Cryptographic Stamp

See more ZATCA Examples

Demonstrates how to create the TLV encoding of the QR code fields, then apply the ECDSA signature and ECDSA public key, and finally insert into the previously signed XML E-Invoice.

Note: This example requires Chilkat v9.5.0.92 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' In Step 1, we applied a signature to an e-invoice Zakat, Tax and Customs Authority (ZATCA) of Saudi Arabia

' This example is Step 2, where we compose the TLV encoding of the QR code, apply the ECDSA signature, and then insert into the signed XML without disturbing the signed XML.

' Construct TLV (Tag-Length-Value) encoding of the QR data.
' We have 5 pieces of data: Seller Name, VAT Number, Time Stamp, Invoice Total, and VAT Total.
' For example:
sellerName = "Firoz Ashraf"
vatNumber = "1234567891"

' The timestamp in QR Code should be based on Invoice Issue Time (KSA-25) and Invoice Issue Date (BT-2). 
' It can either be in format YYYY-MM-DD'T'HH:MM:SS (for local time in KSA) or YYYY-MM-DD'T'HH:MM:SS'Z' (for UTC time or Zulu time)

' Get the current UTC date/time in this format: YYYY-MM-DD'T'HH:MM:SS'Z'
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.CkDateTime")
set dt = CreateObject("Chilkat.CkDateTime")
success = dt.SetFromCurrentSystemTime()
timeStamp = dt.GetAsTimestamp(0)
invoiceTotal = "100.00"
vatTotal = "15.00"

' TLV encode into a Chilkat BinData object.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bdTlv = CreateObject("Chilkat.BinData")

charset = "utf-8"

tag = 1
success = bdTlv.AppendByte(tag)
success = bdTlv.AppendCountedString(1,0,sellerName,charset)
tag = tag + 1
' This is tag 2
success = bdTlv.AppendByte(tag)
success = bdTlv.AppendCountedString(1,0,vatNumber,charset)
tag = tag + 1
' This is tag 3
success = bdTlv.AppendByte(tag)
success = bdTlv.AppendCountedString(1,0,timeStamp,charset)
tag = tag + 1
' This is tag 4
success = bdTlv.AppendByte(tag)
success = bdTlv.AppendCountedString(1,0,invoiceTotal,charset)
tag = tag + 1
' This is tag 5
success = bdTlv.AppendByte(tag)
success = bdTlv.AppendCountedString(1,0,vatTotal,charset)

' ----------------------------------------------------------------------------------------------------------------------------------------------
' For tag 6, we need the SHA256 hash from the signed XML.  This is the DigestValue as shown in the fragment of the XML Signature below:

'     <ds:Reference Id="invoiceSignedData" URI="">
'         <ds:Transforms>
'             <ds:Transform Algorithm="http://www.w3.org/TR/1999/REC-xpath-19991116">
'                 <ds:XPath>not(//ancestor-or-self::ext:UBLExtensions)</ds:XPath>
'             </ds:Transform>
'             <ds:Transform Algorithm="http://www.w3.org/TR/1999/REC-xpath-19991116">
'                 <ds:XPath>not(//ancestor-or-self::cac:Signature)</ds:XPath>
'             </ds:Transform>
'             <ds:Transform Algorithm="http://www.w3.org/TR/1999/REC-xpath-19991116">
'                 <ds:XPath>not(//ancestor-or-self::cac:AdditionalDocumentReference[cbc:ID='QR'])</ds:XPath>
'             </ds:Transform>
'             <ds:Transform Algorithm="http://www.w3.org/2006/12/xml-c14n11"/>
'         </ds:Transforms>
'         <ds:DigestMethod Algorithm="http://www.w3.org/2001/04/xmlenc#sha256"/>
'         <ds:DigestValue>zCp+kF1qzNgXD6AhLq69/CYCklMFSXUmmVPbm4v/76U=</ds:DigestValue>
'     </ds:Reference>

' To get this information, we'll need to load the signed XML into a Chilkat XML object, and then access it.
' Load the XML we previously signed...
signedXmlFilePath = "qa_data/zatca/testing/SignedXML.xml"
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xmlSigned = CreateObject("Chilkat.Xml")
success = xmlSigned.LoadXmlFile(signedXmlFilePath)
If (success = 0) Then
    outFile.WriteLine(xmlSigned.LastErrorText)
    WScript.Quit
End If

' digestValue is a base64 string.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbDigestValue = CreateObject("Chilkat.StringBuilder")
success = xmlSigned.GetChildContentSb("ext:UBLExtensions|ext:UBLExtension|ext:ExtensionContent|sig:UBLDocumentSignatures|sac:SignatureInformation|ds:Signature|ds:SignedInfo|ds:Reference[0]|ds:DigestValue",sbDigestValue)
If (success = 0) Then
    outFile.WriteLine("Failed to get DigestValue from signed XML.")
    WScript.Quit
End If

outFile.WriteLine("DigestValue = " & sbDigestValue.GetAsString())

' Append the DigestValue base64 string to the TLV.
tag = 6
success = bdTlv.AppendByte(tag)
success = bdTlv.AppendByte(sbDigestValue.Length)
success = bdTlv.AppendSb(sbDigestValue,"utf-8")

' ----------------------------------------------------------------------------------------------------------------------------------------------
' Tag 7 will contain the <ds:Signature> value from the signed XML.
' PS> To get the XML path passed to GetChildContentSb, you can copy/paste the signed XML into Chilkat's online tool at https://tools.chilkat.io/xmlParse
' The parsing code that is generated by the online tool will reveal the required path to the element in the XML.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbSignatureValue = CreateObject("Chilkat.StringBuilder")
success = xmlSigned.GetChildContentSb("ext:UBLExtensions|ext:UBLExtension|ext:ExtensionContent|sig:UBLDocumentSignatures|sac:SignatureInformation|ds:Signature|ds:SignatureValue",sbSignatureValue)
If (success = 0) Then
    outFile.WriteLine("Failed to get SignatureValue from signed XML.")
    WScript.Quit
End If

outFile.WriteLine("SignatureValue = " & sbSignatureValue.GetAsString())

' Append the SignatureValue base64 string to the TLV.
tag = 7
success = bdTlv.AppendByte(tag)
success = bdTlv.AppendByte(sbSignatureValue.Length)
success = bdTlv.AppendSb(sbSignatureValue,"utf-8")

' ----------------------------------------------------------------------------------------------------------------------------------------------
' Tag 8 will contain the public key of the signing certificate.
' The signing certificate is available within the signed XML at <ds:X509Certificate>.
x509Certificate = xmlSigned.GetChildContent("ext:UBLExtensions|ext:UBLExtension|ext:ExtensionContent|sig:UBLDocumentSignatures|sac:SignatureInformation|ds:Signature|ds:KeyInfo|ds:X509Data|ds:X509Certificate")
If (xmlSigned.LastMethodSuccess = 0) Then
    outFile.WriteLine("Failed to get X509Certificate from the signed XML.")
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set cert = CreateObject("Chilkat.Cert")
success = cert.SetFromEncoded(x509Certificate)
If (success = 0) Then
    outFile.WriteLine("Failed to load signing certificate from base64.")
    WScript.Quit
End If

' We want to get the cert's public key bytes having this ASN.1 format.
' SEQUENCE (2 elem)
'   SEQUENCE (2 elem)
'     OBJECT IDENTIFIER 1.2.840.10045.2.1 ecPublicKey (ANSI X9.62 public key type)
'     OBJECT IDENTIFIER 1.3.132.0.10 secp256k1 (SECG (Certicom) named elliptic curve)
'   BIT STRING (520 bit) 0000010001110000110111000001111110100110101110110101111000110001110100

' Note: The cert.GetPubKeyDer method was added in Chilkat v9.5.0.92
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bdPubKey = CreateObject("Chilkat.BinData")
success = cert.GetPubKeyDer(1,bdPubKey)
If (success = 0) Then
    outFile.WriteLine("Failed to get certificate's public key.")
    WScript.Quit
End If

' We want to add the binary bytes of the public key (not the base64 string) to the QR code.
tag = 8
success = bdTlv.AppendByte(tag)
success = bdTlv.AppendByte(bdPubKey.NumBytes)
success = bdTlv.AppendBd(bdPubKey)

' Show the public key in base64 format:
outFile.WriteLine("Certificate public key:")
outFile.WriteLine(bdPubKey.GetEncoded("base64"))

' ----------------------------------------------------------------------------------------------------------------------------------------------
' Tag 9 will contain the signature contained in the signing certificate.

' Note: The cert.GetPubKeyDer method was added in Chilkat v9.5.0.92
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bdCertSig = CreateObject("Chilkat.BinData")
success = cert.GetSignature(bdCertSig)
If (success = 0) Then
    outFile.WriteLine("Failed to get certificate's signature.")
    WScript.Quit
End If

' We want to add the binary bytes of the signature (not the base64 string) to the QR code.
tag = 9
success = bdTlv.AppendByte(tag)
success = bdTlv.AppendByte(bdCertSig.NumBytes)
success = bdTlv.AppendBd(bdCertSig)

' Show the cert's signature in hex format:
outFile.WriteLine("Certificate signature:")
outFile.WriteLine(bdCertSig.GetEncoded("hex"))

' ----------------------------------------------------------------------------------------------------------------------------------------------
' At this point the full QR code is contained in bdTlv.
' Get it as a base64 string
qr_base64 = bdTlv.GetEncoded("base64")
outFile.WriteLine("QR: " & qr_base64)

' ----------------------------------------------------------------------------------------------------------------------------------------------
' Insert the QR XML fragment into the previously signed XML -- without disturbing (invalidating) the signature.

' We need to build and insert the following XML fragment under the 
' as a cac:AdditionalDocumentReference just before the "<cac:Signature>" opening tag.

'    <cac:AdditionalDocumentReference>
'         <cbc:ID>QR</cbc:ID>
'         <cac:Attachment>
'             <cbc:EmbeddedDocumentBinaryObject mimeCode="text/plain">BASE64_TLV_CONTENT</cbc:EmbeddedDocumentBinaryObject>
'         </cac:Attachment>
'    </cac:AdditionalDocumentReference>

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xmlQR = CreateObject("Chilkat.Xml")
xmlQR.Tag = "cac:AdditionalDocumentReference"
xmlQR.UpdateChildContent "cbc:ID","QR"
success = xmlQR.UpdateAttrAt("cac:Attachment|cbc:EmbeddedDocumentBinaryObject",1,"mimeCode","text/plain")
xmlQR.UpdateChildContent "cac:Attachment|cbc:EmbeddedDocumentBinaryObject",bdTlv.GetEncoded("base64")

' Load our previously signed XML into a Chilkat StringBuilder.
' We should not load the previously signed XML into a Chilkat XML object because the XML gets loaded into an internal DOM (Document Object Model).
' When re-emitted from the DOM, formatting can change and it would break the XML signature.
' Therefore, we must load into a StringBuilder and insert the new fragment without disturbing the remainder.
' The inserted fragment is ignored because the following transform was included in the XML signature reference:

'             <ds:Transform Algorithm="http://www.w3.org/TR/1999/REC-xpath-19991116">
'                 <ds:XPath>not(//ancestor-or-self::cac:AdditionalDocumentReference[cbc:ID='QR'])</ds:XPath>
'             </ds:Transform>

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbSignedXml = CreateObject("Chilkat.StringBuilder")
success = sbSignedXml.LoadFile(signedXmlFilePath,"utf-8")
If (success = 0) Then
    outFile.WriteLine("Failed to load previously signed XML file.")
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbReplaceStr = CreateObject("Chilkat.StringBuilder")
xmlQR.EmitXmlDecl = 0
xmlQR.EmitCompact = 1
success = sbReplaceStr.Append(xmlQR.GetXml())
success = sbReplaceStr.Append("<cac:Signature>")
success = sbSignedXml.ReplaceFirst("<cac:Signature>",sbReplaceStr.GetAsString())
If (success = 0) Then
    outFile.WriteLine("Did not find <cac:Signature> in the signed XML")
    WScript.Quit
End If

' Save the updated signed XML.
success = sbSignedXml.WriteFile("qa_output/signedXML_withQR.xml","utf-8",0)

' ----------------------------------------
' Verify the updated signed XML to make sure we didn't invalidate the signature...
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.XmlDSig")
set verifier = CreateObject("Chilkat.XmlDSig")
success = verifier.LoadSignatureSb(sbSignedXml)
If (success <> 1) Then
    outFile.WriteLine(verifier.LastErrorText)
    WScript.Quit
End If

' ---------------- This is important -----------------------------------------
' Starting in Chilkat v9.5.0.92, specify "ZATCA" in uncommon options 
' to validate signed XML according to ZATCA needs.
' ----------------------------------------------------------------------------
verifier.UncommonOptions = "ZATCA"

numSigs = verifier.NumSignatures
verifyIdx = 0
Do While verifyIdx < numSigs
    verifier.Selector = verifyIdx
    verified = verifier.VerifySignature(1)
    If (verified <> 1) Then
        outFile.WriteLine(verifier.LastErrorText)
        WScript.Quit
    End If

    verifyIdx = verifyIdx + 1
Loop
outFile.WriteLine("All signatures were successfully verified.")

outFile.Close