VBScript

Yahoo Mail Refresh OAuth2 Access Token

See more Yahoo Mail Examples

Demonstrates how to refresh an OAuth2 Yahoo Mail access token. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' It is assumed we previously obtained an OAuth2 access token.
' This example loads the JSON access token file 
' saved by this example: Get Yahoo Mail OAuth2 Access Token

set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/yahooMail.json")
If (success <> 1) Then
    outFile.WriteLine("Failed to load googleSheets.json")
    WScript.Quit
End If

' The access token JSON looks like this:

' {
'   "access_token": "kCVQdnOdul...LHucA--",
'   "refresh_token": "AIenVWETSo0jklFBVkPS8vVm8E.Dj9ToRG.xDbDYmZ55WIs5t6CZhDkD",
'   "expires_in": 3600,
'   "token_type": "bearer",
'   "xoauth_yahoo_guid": "HGDQCVF6JB4YDOWHITPJFBHCWA"
' }

set oauth2 = CreateObject("Chilkat.OAuth2")

' See Step 5 at https://developer.yahoo.com/oauth2/guide/flows_authcode/
oauth2.TokenEndpoint = "https://api.login.yahoo.com/oauth2/get_token"

' Replace these with actual values.
oauth2.ClientId = "CLIENT_ID"
oauth2.ClientSecret = "CLIENT_SECRET"

' Get the "refresh_token"
oauth2.RefreshToken = jsonToken.StringOf("refresh_token")

' Send the HTTP POST to refresh the access token..
success = oauth2.RefreshAccessToken()
If (success <> 1) Then
    outFile.WriteLine(oauth2.LastErrorText)
    WScript.Quit
End If

' The response contains a new access token, but we must keep
' our existing refresh token for when we need to refresh again in the future.
success = jsonToken.UpdateString("access_token",oauth2.AccessToken)

' Save the new JSON access token response to a file.
set sbJson = CreateObject("Chilkat.StringBuilder")
jsonToken.EmitCompact = 0
success = jsonToken.EmitSb(sbJson)
success = sbJson.WriteFile("qa_data/tokens/yahooMail.json","utf-8",0)

outFile.WriteLine("OAuth2 authorization granted!")
outFile.WriteLine("New Access Token = " & oauth2.AccessToken)

outFile.Close