VBScript Requires Chilkat v11.0.0+

List Yahoo Mail IMAP Mailboxes

See more Yahoo Mail Examples

List Yahoo Mail mailboxes. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  This example assumes the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  See Get Yahoo Mail OAuth2 Access Token for Desktop App 
'  for sample code showing how to obtain a Yahoo Mail access token.

'  In this example, our access token was previously saved to the following file which contains JSON like this:
'  {
'    "access_token": "kCVQdnOdul...LHucA--",
'    "refresh_token": "AIenVXETSo0jklFBVkPS8vVm8E.Ej9ToRG.xDbDYmZ65WIs5t6CZhDrD",
'    "expires_in": 3600,
'    "token_type": "bearer",
'    "xoauth_yahoo_guid": "HGDQCVF5JB4YDOWHITQJFBHCWA"
'  }

set json = CreateObject("Chilkat.JsonObject")
success = json.LoadFile("qa_data/tokens/yahooMail.json")
If (success <> 1) Then
    outFile.WriteLine("Failed to load Yahoo Mail access token file.")
    WScript.Quit
End If

accessToken = json.StringOf("access_token")

'  Do OAuth2 authentication by using the access token as the password in the Login method below...
set imap = CreateObject("Chilkat.Imap")

imap.Ssl = 1
imap.Port = 993

'  Connect to the Yahoo IMAP server.
success = imap.Connect("imap.mail.yahoo.com")
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

'  Indicate that XOAUTH2 authentication is to be used:
imap.AuthMethod = "XOAUTH2"

'  Login
'  Use the email address of the Yahoo Mail account that granted authorization.
success = imap.Login("user@yahoo.com",accessToken)
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
Else
    outFile.WriteLine("Successfully authenticated with Yahoo IMAP using XOAUTH2!")
End If

'  Get the list of mailboxes.
refName = ""
wildcardedMailbox = "*"
subscribed = 0

set mboxes = CreateObject("Chilkat.Mailboxes")
success = imap.MbxList(subscribed,refName,wildcardedMailbox,mboxes)
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

i = 0
Do While i < mboxes.Count
    outFile.WriteLine(mboxes.GetName(i))
    i = i + 1
Loop

'  Sample output looks like this:

'  Archive
'  Bulk Mail
'  Draft
'  Inbox
'  Inbox/emailsWithAttach
'  Inbox/test
'  Sent
'  Trash

'  Disconnect from the IMAP server.
success = imap.Disconnect()

outFile.Close