(VBScript) Verify XML Signature having KeyInfo / X509Data / X509IssuerSerial

This example demonstrates how to verify an XML Digital Signature where the KeyInfo element contains an X509Data element,
which in turn contains an X509IssuerSerial element which contains only the issuing cert's distinguished name and the signing cert's serial number.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The SOAP XML with digital signature verified in this example is available at 
' https://www.chilkatsoft.com/exampleData/sigWithX509IssuerSerial.xml

signedSoapXmlUrl = "https://www.chilkatsoft.com/exampleData/sigWithX509IssuerSerial.xml"

' First, let's get the signed SOAP XML..
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbXml = CreateObject("Chilkat.StringBuilder")
success = http.QuickGetSb(signedSoapXmlUrl,sbXml)
If (success <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' The signed XML downloaded from the above URL contains the following.

' <?xml version="1.0" encoding="UTF-8" standalone="no" ?>
' <SOAP-ENV:Envelope xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/">
'     <SOAP-ENV:Header>
'         <wsse:Security xmlns:wsse="http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-wssecurity-secext-1.0.xsd" SOAP-ENV:mustUnderstand="1"><ds:Signature xmlns:ds="http://www.w3.org/2000/09/xmldsig#"><ds:SignedInfo><ds:CanonicalizationMethod Algorithm="http://www.w3.org/2001/10/xml-exc-c14n#"><InclusiveNamespaces xmlns="http://www.w3.org/2001/10/xml-exc-c14n#" PrefixList="wsse SOAP-ENV"/></ds:CanonicalizationMethod><ds:SignatureMethod Algorithm="http://www.w3.org/2001/04/xmldsig-more#rsa-sha256"/><ds:Reference URI="#Body"><ds:Transforms><ds:Transform Algorithm="http://www.w3.org/2001/10/xml-exc-c14n#"/></ds:Transforms><ds:DigestMethod Algorithm="http://www.w3.org/2000/09/xmldsig#sha1"/><ds:DigestValue>PIiVPpuMc1jGpWaL8ftzTOcc4gc=</ds:DigestValue></ds:Reference></ds:SignedInfo><ds:SignatureValue>Rlta8LplnFH0q8L+UeVmh4Smdn6oVETi4RoUmpT/KQX3RNAIOdCVE3b7gjmx5+3vp3DhjphOsZvW6dXzkI46xt9pD5otp3b/ZppGqKzltggo9gyQtPvJ8ltJZqVKYOGo5uElRFF/xm/zcx5Y3E14t+LYVSlv2lbem/zZ5zQ7ai8DmGD33id7nGu+MXVwb3kGkJFYoB/GOXtwsep+bcilMglTp8/7SBfBaVFKxWVBp4N2NW7bGlyDct8FaCk9hXQDNm/kqne9GU87tgh8/rbsFCYgyqIRMIvMPvhRWr2EKdEKyLtlZ8w0KYJYpgsf4T7SDghemzXkJoJPrfUQmHudIw==</ds:SignatureValue><ds:KeyInfo><ds:X509Data><ds:X509IssuerSerial><ds:X509IssuerName>CN=Test Company, C=AU, ST=Some-State, O=Internet Widgits Pty Ltd</ds:X509IssuerName><ds:X509SerialNumber>00</ds:X509SerialNumber></ds:X509IssuerSerial></ds:X509Data></ds:KeyInfo></ds:Signature></wsse:Security>
'     </SOAP-ENV:Header>
'     <SOAP-ENV:Body xmlns:SOAP-SEC="http://schemas.xmlsoap.org/soap/security/2000-12" SOAP-SEC:id="Body">
'         <z:FooBar xmlns:z="http://example.com" />
'     </SOAP-ENV:Body>
' </SOAP-ENV:Envelope>
' 

' Note: We don't have everything we need to verify the signature.
' The KeyInfo part of the Signature contains only the issuer's distinguished name (DN)
' and the signing cert's serial number.  We must obtain the certificate locally using
' this information.  
' 
' On a Windows system, if the matching certificate is already installed in the registry-based
' certificate stores, then your application does not need to do anything.  Chilkat will automatically
' locate and use the matching certificate installed on the Windows system.
' 
' This example will assume we're not on a Windows system, or that the matching certificate
' is not already installed on the system.
' 

' One strategy for providing certificates to the application doing the XML signature verification 
' is to load all possible certificates into an in-memory XmlCertVault beforehand, and then call
' UseCertVault to allow for Chilkat to automatically find the matching cert from the pre-loaded certificates.
' We'll do that here with the one certificate that we already know is the matching certificate.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbCertPem = CreateObject("Chilkat.StringBuilder")
success = http.QuickGetSb("https://chilkatdownload.com/example_data/testcertificate.pem",sbCertPem)
If (success <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Create a cert vault and add the certificates.
' In this example, we're only adding a single certificate.  An application
' could load many certificates into the cert vault..
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.XmlCertVault")
set certVault = CreateObject("Chilkat.XmlCertVault")
success = certVault.AddCertString(sbCertPem.GetAsString())
If (success <> 1) Then
    outFile.WriteLine(certVault.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.XmlDSig")
set verifier = CreateObject("Chilkat.XmlDSig")

' Tell the verifier to use the certVault as a source for locating
' matching certificates.
success = verifier.UseCertVault(certVault)

success = verifier.LoadSignatureSb(sbXml)
If (success <> 1) Then
    outFile.WriteLine(verifier.LastErrorText)
    WScript.Quit
End If

bVerified = verifier.VerifySignature(1)
If (bVerified <> 1) Then
    outFile.WriteLine(verifier.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Signature verified!")

outFile.Close