(VBScript) Verify XML Digital Signature having KeyName

Demonstrates how to verify an XML digital signature where the KeyInfo part contains the KeyName element.
In this case, the public key is not specifically stored in the signed XML.
Rather, application specific information about the key is stored in the KeyName element.
This example uses the KeyName to find and matching public key.

This example requires Chilkat v9.5.0.69 or greater.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' The signed XML to be verified in this example contains the following:
' 
' <?xml version="1.0" encoding="UTF-8" standalone="no"?>
' <Envelope>
'   <Header>
'     <Security>
'     <ds:Signature xmlns:ds="http://www.w3.org/2000/09/xmldsig#"><ds:SignedInfo><ds:CanonicalizationMethod Algorithm="http://www.w3.org/2001/10/xml-exc-c14n#"/><ds:SignatureMethod Algorithm="http://www.w3.org/2009/xmldsig11#dsa-sha256"/><ds:Reference URI="#abc"><ds:Transforms><ds:Transform Algorithm="http://www.w3.org/2001/10/xml-exc-c14n#"/></ds:Transforms><ds:DigestMethod Algorithm="http://www.w3.org/2001/04/xmlenc#sha256"/><ds:DigestValue>XTjDIHSEsDNTO9yn4cKtyXjRUjPFXkOQOLYI5mueZhk=</ds:DigestValue></ds:Reference></ds:SignedInfo><ds:SignatureValue>NXOIMevGCqFl0Dwtp2KkqkT05GRV8CjmHZ9LhFpt8/d7+lkIi7mITA==</ds:SignatureValue><ds:KeyInfo><ds:KeyName>dsaKey_123</ds:KeyName></ds:KeyInfo></ds:Signature></Security>
'   </Header>
'   <Body Id="abc">
'     <z:FooBar xmlns:z="https://www.example-code.com"/>
'   </Body>
' </Envelope>
' 

' The above XML is available at https://www.chilkatsoft.com/exampleData/signedUsingKeyName.xml
' First we'll fetch the signed XML:

url = "https://www.chilkatsoft.com/exampleData/signedUsingKeyName.xml"
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbXml = CreateObject("Chilkat.StringBuilder")
success = http.QuickGetSb(url,sbXml)
If (success <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.XmlDSig")
set verifier = CreateObject("Chilkat.XmlDSig")

' Load the XML containing the signature to be verified.
success = verifier.LoadSignatureSb(sbXml)
If (success <> 1) Then
    outFile.WriteLine(verifier.LastErrorText)
    WScript.Quit
End If

' (The Chilkat XML Digital Signature API has the capability to handle XML documents with multiple signatures.
' We know in advance that this signed XML has just one Signature, so we leave the dsig.Selector property at the
' default value of 0.)

' Let's get the KeyInfo XML so we can then get the KeyName.
' xmlKeyInfo is a Chilkat.Xml
Set xmlKeyInfo = verifier.GetKeyInfo()
If (verifier.LastMethodSuccess = 0) Then
    outFile.WriteLine("There is no KeyInfo available in the Signature.")
    WScript.Quit
End If

' Examine the XML:
outFile.WriteLine(xmlKeyInfo.GetXml())

' The KeyInfo XML that is returned looks like this:
' 
' 	<ds:KeyInfo>
' 	    <ds:KeyName>dsaKey_123</ds:KeyName>
' 	</ds:KeyInfo>
' 

' Get the KeyName.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbKeyName = CreateObject("Chilkat.StringBuilder")
success = sbKeyName.Append(xmlKeyInfo.GetChildContent("*:KeyName"))

' sbKeyName contains "dsaKey_123"
outFile.WriteLine(sbKeyName.GetAsString())

' The application now locates and loads the public key for verification
' based on the key name.  This example will do the following:
' If the key name equals "dsaKey_123", then load the DSA key from
' "qa_data/dsa/dsa1024_public.pem"
' 

If (sbKeyName.ContentsEqual("dsaKey_123",0) = 0) Then
    outFile.WriteLine("I don't know this key...")
    WScript.Quit
End If

' The DSA public key used in this example is available at:
' https://www.chilkatsoft.com/exampleData/dsa1024_public.zip
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.PublicKey")
set pubKey = CreateObject("Chilkat.PublicKey")
success = pubKey.LoadFromFile("qa_data/dsa/dsa1024_public.pem")
If (success <> 1) Then
    outFile.WriteLine(pubKey.LastErrorText)
    WScript.Quit
End If

' Provide the DSA public key to the XML DSig verifier:
success = verifier.SetPublicKey(pubKey)

' Verify the signature
bVerified = verifier.VerifySignature(1)
outFile.WriteLine("Signature verified = " & bVerified)

outFile.Close