(VBScript) Verify XML Digital Signature

Verifies XML signatures in an XML file.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbXml = CreateObject("Chilkat.StringBuilder")
success = sbXml.LoadFile("qa_data/xml_dsig_verify/csioz_sample.xml","utf-8")
If (success <> 1) Then
    outFile.WriteLine("Failed to load XML file.")
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.XmlDSig")
set dsig = CreateObject("Chilkat.XmlDSig")

' First load the XML containing the signatures to be verified.
success = dsig.LoadSignatureSb(sbXml)
If (success <> 1) Then
    outFile.WriteLine(dsig.LastErrorText)
    WScript.Quit
End If

' It's possible that an XML document can contain multiple signatures.
' Each can be verified as follows:
i = 0
Do While i < dsig.NumSignatures
    ' Select the Nth signature by setting the Selector property.
    dsig.Selector = i

    ' The bVerifyReferenceDigests argument determines if we want
    ' to also verify each reference digest.  If set to 0,
    ' then only the SignedInfo part of the Signature is verified.
    bVerifyReferenceDigests = 1
    bVerified = dsig.VerifySignature(bVerifyReferenceDigests)
    outFile.WriteLine("Signature " & (i + 1) & " verified = " & bVerified)

    i = i + 1
Loop

outFile.Close