(VBScript) Create XML Digital Signature using HMAC Key

Demonstrates how to create an XML digital signature using an HMAC key.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Signs the following XML using an HMAC key.

' <?xml version="1.0" encoding="UTF-8" standalone="no"?>
' <collection Id="root">
' 	<album>
' 		<title>Questions, unanswered</title>
' 		<artist>Steve and the flubberblubs</artist>
' 		<year>1989</year>
' 		<t:tracks xmlns:t="http://test.xades4j/tracks">
' 			<t:song length="4:05" tracknumber="1">
' 				<t:title>What do you know?</t:title>
' 				<t:artist>Steve and the flubberblubs</t:artist>
' 				<t:lastplayed>2006-10-17-08:31</t:lastplayed>
' 			</t:song>
' 			<t:song length="3:45" tracknumber="2">
' 				<t:title>Who do you know?</t:title>
' 				<t:artist>Steve and the flubberblubs</t:artist>
' 				<t:lastplayed>2006-10-17-08:35</t:lastplayed>
' 			</t:song>
' 			<t:song length="5:14" tracknumber="3">
' 				<t:title>When do you know?</t:title>
' 				<t:artist>Steve and the flubberblubs</t:artist>
' 				<t:lastplayed>2006-10-17-08:39</t:lastplayed>
' 			</t:song>
' 			<t:song length="4:19" tracknumber="4">
' 				<t:title>Do you know?</t:title>
' 				<t:artist>Steve and the flubberblubs</t:artist>
' 				<t:lastplayed>2006-10-17-08:44</t:lastplayed>
' 			</t:song>
' 		</t:tracks>
' 	</album>
' </collection>
' 

' The above XML is available at https://www.chilkatsoft.com/exampleData/flubberblub.xml
' Fetch the XML and then sign it..

url = "https://www.chilkatsoft.com/exampleData/flubberblub.xml"
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbXml = CreateObject("Chilkat.StringBuilder")
success = http.QuickGetSb(url,sbXml)
If (success <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.XmlDSigGen")
set xmlSigGen = CreateObject("Chilkat.XmlDSigGen")

' The Signature will be inserted under the "collection" element.
xmlSigGen.SigLocation = "collection"

' Sign everything in <collection Id="root"> ... </collection>
success = xmlSigGen.AddSameDocRef("root","sha256","C14N","","")

' Specify the HMAC key.
' For example, if the HMAC key is to be the us-ascii bytes of the string "secret",
' the HMAC key can be set in any of the following ways (and also more ways not shown here..)
success = xmlSigGen.SetHmacKey("secret","ascii")
' or
success = xmlSigGen.SetHmacKey("c2VjcmV0","base64")
' or
success = xmlSigGen.SetHmacKey("736563726574","hex")

' Sign the XML..
success = xmlSigGen.CreateXmlDSigSb(sbXml)
If (success <> 1) Then
    outFile.WriteLine(xmlSigGen.LastErrorText)
    WScript.Quit
End If

' Examine the signed XML:
outFile.WriteLine(sbXml.GetAsString())

' The output is:
' 
' <?xml version="1.0" encoding="UTF-8" standalone="no"?>
' <collection Id="root">
' 	<album>
' 		<title>Questions, unanswered</title>
' 		<artist>Steve and the flubberblubs</artist>
' 		<year>1989</year>
' 		<t:tracks xmlns:t="http://test.xades4j/tracks">
' 			<t:song length="4:05" tracknumber="1">
' 				<t:title>What do you know?</t:title>
' 				<t:artist>Steve and the flubberblubs</t:artist>
' 				<t:lastplayed>2006-10-17-08:31</t:lastplayed>
' 			</t:song>
' 			<t:song length="3:45" tracknumber="2">
' 				<t:title>Who do you know?</t:title>
' 				<t:artist>Steve and the flubberblubs</t:artist>
' 				<t:lastplayed>2006-10-17-08:35</t:lastplayed>
' 			</t:song>
' 			<t:song length="5:14" tracknumber="3">
' 				<t:title>When do you know?</t:title>
' 				<t:artist>Steve and the flubberblubs</t:artist>
' 				<t:lastplayed>2006-10-17-08:39</t:lastplayed>
' 			</t:song>
' 			<t:song length="4:19" tracknumber="4">
' 				<t:title>Do you know?</t:title>
' 				<t:artist>Steve and the flubberblubs</t:artist>
' 				<t:lastplayed>2006-10-17-08:44</t:lastplayed>
' 			</t:song>
' 		</t:tracks>
' 	</album>
' <ds:Signature xmlns:ds="http://www.w3.org/2000/09/xmldsig#"><ds:SignedInfo><ds:CanonicalizationMethod Algorithm="http://www.w3.org/2001/10/xml-exc-c14n#"/><ds:SignatureMethod Algorithm="http://www.w3.org/2001/04/xmldsig-more#hmac-sha256"/><ds:Reference URI="#root"><ds:Transforms><ds:Transform Algorithm="http://www.w3.org/2000/09/xmldsig#enveloped-signature"/></ds:Transforms><ds:DigestMethod Algorithm="http://www.w3.org/2001/04/xmlenc#sha256"/><ds:DigestValue>rD/g8soqKz8EiPUBhEWfcQacS0ta4ULHX3dKMEH6ZoQ=</ds:DigestValue></ds:Reference></ds:SignedInfo><ds:SignatureValue>R8dXP95VRYJBfL6d0Peogybdk27+R+JIfX8jnVu0NOI=</ds:SignatureValue></ds:Signature></collection>
' 

outFile.Close