VBScript

Handling Namespaces in XML Tags

See more XML Examples

Demonstrates new features added in Chilkat v9.5.0.77 for helping with namespace prefixed tags. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' First create some XML using namespace prefixed tags.

' Create this XML. 
' Use this online tool to generate the code from sample XML: 
' Generate Code to Create XML

' <soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
'    xmlns:scm="http://www.springcm.com/atlas/webservices/v201308/scm/">
'    <soapenv:Header/>
'    <soapenv:Body>
'       <scm:AccountGetCurrent>
'          <scm:token>123</scm:token>
'       </scm:AccountGetCurrent>
'    </soapenv:Body>
' </soapenv:Envelope>

set xml = CreateObject("Chilkat.Xml")
xml.Tag = "soapenv:Envelope"
success = xml.AddAttribute("xmlns:soapenv","http://schemas.xmlsoap.org/soap/envelope/")
success = xml.AddAttribute("xmlns:scm","http://www.springcm.com/atlas/webservices/v201308/scm/")
xml.UpdateChildContent "soapenv:Header",""
xml.UpdateChildContent "soapenv:Body|scm:AccountGetCurrent|scm:token","123"

' Go to the "Body" tag, regardless of namespace prefix.
' xmlBody is a Chilkat.Xml
Set xmlBody = xml.FindChild("*:Body")
If (xml.LastMethodSuccess <> 1) Then
    outFile.WriteLine("Body child not found.")
    WScript.Quit
End If

' Get the full tag w/ namespace prefix:
' Output is "soapenv:Body"
outFile.WriteLine(xmlBody.Tag)

' Get the namespace prefix:
' Output is "soapenv"
outFile.WriteLine(xmlBody.TagNsPrefix)

' Get the unprefixed tag:
' Output is "Body"
outFile.WriteLine(xmlBody.TagUnprefixed)

' Check to see if the unprefixed tag equals "Body"
isBodyTag = xmlBody.TagUnpEquals("Body")
outFile.WriteLine("isBodyTag = " & isBodyTag)

' Check to see if the namespace prefix equals "soapenv";
isSoapenv = xmlBody.TagNsEquals("soapenv")
outFile.WriteLine("isSoapenv = " & isSoapenv)

' Change just the namespace prefix of the tag
xmlBody.TagNsPrefix = "se"
' The tag has changed from "soapenv:Body" to "se:Body"
outFile.WriteLine(xmlBody.Tag)

' Change the unprefixed part of the tag.
xmlBody.TagUnprefixed = "Bodie"
' The tag has changed from "se:Body" to "se:Bodie"
outFile.WriteLine(xmlBody.Tag)


outFile.Close