VBScript

Iterate over Direct Child Nodes by Index

See more XML Examples

Demonstrates some ways to iterate over direct child nodes by index.

The input XML, available at http://www.chilkatsoft.com/data/get_child.xml, is this:

<root>
    <fruit color="red">apple</fruit>
    <fruit color="green">pear</fruit>
    <veg color="orange">carrot</veg>
    <meat animal="cow">beef</meat>
    <xyz>
        <fruit color="blue">blueberry</fruit>
        <veg color="green">broccoli</veg>
    </xyz>
    <fruit color="purple">grape</fruit>
    <cheese color="yellow">cheddar</cheese>
</root>

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

set xml = CreateObject("Chilkat.Xml")

' The sample input XML is available at http://www.chilkatsoft.com/data/get_child.xml
success = xml.LoadXmlFile("get_child.xml")
If (success <> 1) Then
    outFile.WriteLine(xml.LastErrorText)
    WScript.Quit
End If

' The NumChildren property contains the number of direct
' child nodes.  Note: The child nodes under "xyz" are NOT
' direct children of "root".  Therefore, the "root" node has
' 7 direct children
outFile.WriteLine("NumChildren = " & xml.NumChildren)

' Iterate over the direct children by index. The first child
' is at index 0.

For i = 0 To xml.NumChildren - 1
    '  access the tag and content directly by index:
    outFile.WriteLine(i & ": " & xml.GetChildTagByIndex(i) & " : " & xml.GetChildContentByIndex(i))

Next
outFile.WriteLine("-----")

' Do the same as the above loop, but get the child node
' and access the Tag and Content properties:
For i = 0 To xml.NumChildren - 1
    ' child is a Chilkat.Xml
    Set child = xml.GetChild(i)
    outFile.WriteLine(i & ": " & child.Tag & " : " & child.Content)

Next
outFile.WriteLine("-----")

' Do the same as the above loop, but instead of creating
' a new object instance for each child, call GetChild2 to
' update the object's reference instead.
For i = 0 To xml.NumChildren - 1
    ' Navigate to the Nth child.  
    success = xml.GetChild2(i)
    outFile.WriteLine(i & ": " & xml.Tag & " : " & xml.Content)
    ' Navigate back up to the parent:
    success = xml.GetParent2()
Next
outFile.WriteLine("-----")

' Notice that the Content of the "xyz" node is empty.  This is correct.
' The "xyz" node has no Content, but 2 direct children

outFile.Close