(VBScript) Fetch ISBN XML from isbndb.com and Parse

Demonstrates sending a query to isbndb.com and parsing the XML response.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' The access_key in this URL is a valid access key, but limited to 100 queries per day.
' If the key does not work, it may be that others were testing and exhausted the limit.
strXml = http.QuickGetStr("http://isbndb.com/api/books.xml?access_key=OV8L2Y9I&results=details&index1=isbn&value1=0443074348")
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXml(strXml)

' The XML returned for this URL is the following:

' <?xml version="1.0" encoding="UTF-8" ?>

' <ISBNdb server_time="2007-10-25T14:07:25Z">
'     <BookList total_results="1" page_size="10" page_number="1" shown_results="1">
'         <BookData book_id="diagnostic_histopathology_of_tumors_2_volume_set_with_cd_rom" isbn="0443074348">
'             <Title>Diagnostic Histopathology of Tumors: 2-Volume Set with CD-ROMs</Title>
'             <TitleLong>Diagnostic Histopathology of Tumors: 2-Volume Set with CD-ROMs (Diagnostic Histopathology of Tumors (Fletcher))</TitleLong>
'             <AuthorsText>Christopher D. M. Fletcher (Editor)</AuthorsText>
'             <PublisherText publisher_id="churchill_livingstone">Churchill Livingstone</PublisherText>
'             <Details dewey_decimal="616" physical_description_text="2166 pages" language="" edition_info="Hardcover; 2007-03-13" dewey_decimal_normalized="616" lcc_number="" change_time="2006-12-13T14:53:42Z" price_time="2007-10-25T01:12:13Z" />
'         </BookData>
'     </BookList>
' </ISBNdb>

' First, navigate to the BookData node:
success = xml.FirstChild2()
success = xml.FirstChild2()

' Show the Title and AuthorsText:
outFile.WriteLine(xml.GetChildContent("Title"))
outFile.WriteLine(xml.GetChildContent("AuthorsText"))

' Show the publisher_id attribute of the PublisherText node:

' xml2 is a Chilkat.Xml
Set xml2 = xml.FindChild("PublisherText")
outFile.WriteLine(xml2.GetAttrValue("publisher_id"))

' Save the XML to a file:
success = xml.SaveXml("book.xml")

outFile.Close