VBScript

Insert XML into existing XML by calling InsertChildTreeAfter

See more XML Examples

Demonstrates how to insert an XML tree or subtree into another XML document using the InsertChildTreeAfter method. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Build the 1st XML document:
' <x1>
'     <a1>1</a1>
'     <a2>2</a2>
'     <a3>3</a3>
' </x1>

set xml = CreateObject("Chilkat.Xml")
xml.Tag = "x1"
xml.UpdateChildContent "a1","1"
xml.UpdateChildContent "a2","2"
xml.UpdateChildContent "a3","3"

' Build a 2nd XML document:

' <x2>
'   <b1>11</b1>
'   <b2>22</b2>
'   <b3>33</b3>
' </x2>

set xml2 = CreateObject("Chilkat.Xml")
xml2.Tag = "x2"
xml2.UpdateChildContent "b1","11"
xml2.UpdateChildContent "b2","22"
xml2.UpdateChildContent "b3","33"

' We want to insert xml2 into xml to get this:

' <x1>
'     <a1>1</a1>
'     <x2>
'         <b1>11</b1>
'         <b2>22</b2>
'         <b3>33</b3>
'     </x2>
'     <a2>2</a2>
'     <a3>3</a3>
' </x1>

' Insert xml2 after "a1"

index = xml.TagIndex("a1")
If (index < 0) Then
    outFile.WriteLine("a1 not found.")
    WScript.Quit
End If

xml.InsertChildTreeAfter index,xml2

outFile.WriteLine(xml.GetXml())

' The result is:

' <x1>
'     <a1>1</a1>
'     <x2>
'         <b1>11</b1>
'         <b2>22</b2>
'         <b3>33</b3>
'     </x2>
'     <a2>2</a2>
'     <a3>3</a3>
' </x1>

' Note: xml2 now points to the subtree within xml.
' For example, update "b3" and then see how it's updated within the merged document:
xml2.UpdateChildContent "b3","33333333"

outFile.WriteLine(xml.GetXml())

' The result:

' <x1>
'     <a1>1</a1>
'     <x2>
'         <b1>11</b1>
'         <b2>22</b2>
'         <b3>33333333</b3>
'     </x2>
'     <a2>2</a2>
'     <a3>3</a3>
' </x1>

outFile.Close