(VBScript) Xml TagPath Property Explained

Demonstrates and explains the TagPath property.

Note: The TagPath property was introduced in Chilkat v9.5.0.77

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")

' Load some XML:
success = xml.LoadXml("<a><bbb><ccc><ddd>1</ddd><ddd><z>zzz</z></ddd><ddd>3</ddd></ccc></bbb></a>")

outFile.WriteLine(xml.GetXml())

' This is what we have:

' <?xml version="1.0" encoding="utf-8"?>
' <a>
'     <bbb>
'         <ccc>
'             <ddd>1</ddd>
'             <ddd>
'                 <z>zzz</z>
'             </ddd>
'             <ddd>3</ddd>
'         </ccc>
'     </bbb>
' </a>

' The TagPath property is read-only property that returns the unique path to the
' node from the document root.

' For example:
found = xml.SearchForTag2(xml,"z")
If (found = 1) Then
    ' We found a node having the tag "z".
    ' The TagPath property tells us the location in the document.
    tagPath = xml.TagPath
    outFile.WriteLine(tagPath)

    ' The tagPath is bbb|ccc|ddd[1]|z

    ' If we to back to the document root, we can get to the given node via the tagPath.
    xml.GetRoot2 
    outFile.WriteLine(xml.Tag)
    ' The root tag is "a".

    ' Follow the tagPath to the "z" node:
    found = xml.FindChild2(tagPath)
    outFile.WriteLine("found = " & found & ", tag = " & xml.Tag)
    ' We are now at "z".

End If


outFile.Close