VBScript

Demonstrate the XML FindNextRecord Method

See more XML Examples

Imagine we have an XML file as follows:

<CompleteMultipartUpload>
  <Part>
    <PartNumber>1</PartNumber>
    <ETag>abc</ETag>
  </Part>
  <Part>
    <PartNumber>2</PartNumber>
    <ETag>def</ETag>
  </Part>
  <Part>
    <PartNumber>3</PartNumber>
    <ETag>ghi</ETag>
  </Part>
</CompleteMultipartUpload>

We want to find the record where PartNumber = 2. To do so, we simply position ourselves at the first "Part" tag, and then call FindNextRecord. (See below..) VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

set xml = CreateObject("Chilkat.Xml")

success = xml.LoadXmlFile("qa_data/xml/multipartUpload.xml")

' Position ourselves at the 1st record.
success = xml.GetChild2(0)

' foundRec is a Chilkat.Xml
Set foundRec = xml.FindNextRecord("PartNumber","2")
If (xml.LastMethodSuccess = 1) Then
    outFile.WriteLine("Found the record where PartNumber = 2.")
    outFile.WriteLine(foundRec.GetXml())

    ' Let's examine the ETag for this record...
    outFile.WriteLine("ETag for PartNumber 2 = " & foundRec.GetChildContent("ETag"))

Else
    outFile.WriteLine("No record exists where PartNumber = 2.")
End If

' What if we want to find the record where ETag = "abc"?
' foundRec is a Chilkat.Xml
Set foundRec = xml.FindNextRecord("ETag","abc")
If (xml.LastMethodSuccess = 1) Then
    outFile.WriteLine("Found the record where ETag = abc")
    outFile.WriteLine(foundRec.GetXml())

    ' Let's examine the PartNumber for this record...
    outFile.WriteLine("Part number for Etag(abc) = " & foundRec.GetChildContent("PartNumber"))

Else
    outFile.WriteLine("No record exists where ETag = abc.")
End If

' Go back to the XML root..
xml.GetRoot2 

outFile.Close