(VBScript) Encrypting and Decrypting Content

Demonstrates how to encrypt and decrypt the content of an XML node using 128-bit CBC AES encryption.

The input XML, available at http://www.chilkatsoft.com/data/fox.xml, is this:

<root>
    <fox1>The quick brown fox jumps over the lazy dog</fox1>
    <fox2>The quick brown fox jumps over the lazy dog
        <child1>ABC</child1>
        <child2>XYZ</child2>
    </fox2>
</root>

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")

' The sample input XML is available at http://www.chilkatsoft.com/data/fox.xml
success = xml.LoadXmlFile("fox.xml")
If (success <> 1) Then
    outFile.WriteLine(xml.LastErrorText)
    WScript.Quit
End If

' Navigate to the "fox1" node, which is the 1st child:
success = xml.FirstChild2()

' Encrypt the content:
success = xml.EncryptContent("myPassword")

' Navigate back to the root:
xml.GetRoot2 

' Examine the new XML document:
outFile.WriteLine(xml.GetXml())

' This is the XML w/ the encrypted content:
' <root>
'     <fox1>1hTtf7XmO+78H+OIr5eWHIuXxP78KPeYrZbsD0HX4negO9ZRqYMBY4s46sPNp+Q+
'     </fox1>
'     <fox2>The quick brown fox jumps over the lazy dog
'         <child1>ABC</child1>
'         <child2>XYZ</child2>
'     </fox2>
' </root>

' Now decrypt and show that the original content was restored:
success = xml.FirstChild2()
success = xml.DecryptContent("myPassword")
xml.GetRoot2 
outFile.WriteLine(xml.GetXml())

' Now encrypt the content of the "fox2" node.
' First navigate to the "fox2" child.
success = xml.FindChild2("fox2")
success = xml.EncryptContent("myPassword")
xml.GetRoot2 
outFile.WriteLine(xml.GetXml())

' This is the XML w/ the "fox2" encrypted content:

' <root>
'     <fox1>The quick brown fox jumps over the lazy dog</fox1>
'     <fox2>1hTtf7XmO+78H+OIr5eWHIuXxP78KPeYrZbsD0HX4negO9ZRqYMBY4s46sPNp+Q+
' 
'         <child1>ABC</child1>
'         <child2>XYZ</child2>
'     </fox2>
' </root>

' Notice that the *content* of the node is encrypted.  The child nodes are NOT encrypted.
' This is intentional.  To encrypt the content + the subtrees rooted at a given node, 
' one would call ZipTree to transform the content and subtrees
' to Base64-encoded compressed content, and then call
' EncryptContent to encrypt.

' Finally, decrypt the "fox2" content:
success = xml.FindChild2("fox2")
success = xml.DecryptContent("myPassword")
xml.GetRoot2 
outFile.WriteLine(xml.GetXml())

outFile.Close