(VBScript) AddAttribute - Insert New Attribute in an XML Node

Demonstrates adding an name=value attribute to an XML element.

This example uses the XML sample file here: sample1.xml. The sample1.xml file contains this content:

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")

success = xml.LoadXmlFile("qa_data/xml/sample1.xml")
If (success <> 1) Then
    outFile.WriteLine(xml.LastErrorText)
    WScript.Quit
End If

' Navigate to the "books" element:
bFound = xml.FindChild2("books")
If (bFound = 0) Then
    outFile.WriteLine("No books child found!")
    WScript.Quit
End If

numChildren = xml.NumChildren

i = 0
Do While i < numChildren

    ' Navigate to the Nth book 
    success = xml.GetChild2(i)

    ' Display the book title:
    outFile.WriteLine(xml.GetAttrValue("title"))

    ' Add a new integer attribute:
    ' Should never fail..
    success = xml.AddAttributeInt("bookId",i)

    ' Add a new unread="yes" attribute:
    success = xml.AddAttribute("unread","yes")

    ' Navigate back up to the parent:
    success = xml.GetParent2()

    i = i + 1
Loop

' Navigate back to the document root:
xml.GetRoot2 

' Save the updated document:
success = xml.SaveXml("modified.xml")
If (success <> 1) Then
    outFile.WriteLine(xml.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(xml.GetXml())

outFile.Close