(VBScript) Xero Upload Attachment

Demonstrates how to upload an attachment to Xero.

For more information, see https://developer.xero.com/documentation/api/attachments#POST

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' Important: Make sure your OAuth2 access token was obtained with the scope "accounting.attachments"
' included in the list of scopes.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/xero-access-token.json")
If (success = 0) Then
    outFile.WriteLine(jsonToken.LastErrorText)
    WScript.Quit
End If

http.AuthToken = jsonToken.StringOf("access_token")

' Replace the value here with an actual tenant ID obtained from this example:
' Get Xero Tenant IDs
http.SetRequestHeader "Xero-tenant-id","83299b9e-5747-4a14-a18a-a6c94f824eb7"

http.Accept = "application/json"

url = "https://api.xero.com/api.xro/2.0/{$Endpoint}/{$Guid}/Attachments/{$Filename}"

' Endpoint can be Invoices, Receipts, CreditNotes, PurchaseOrders, etc.
success = http.SetUrlVar("Endpoint","Invoices")

' Guid is the ID of the item, such as the InvoiceID.
success = http.SetUrlVar("Guid","0032f627-3156-4d30-9b1c-4d3b994dc921")

' Filename is the filename of the attachment you are uploading.
success = http.SetUrlVar("Filename","penguins.jpg")

' Load the file to be uploaded (from the local filesystem).
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bd = CreateObject("Chilkat.BinData")
success = bd.LoadFile("qa_data/jpg/penguins.jpg")
If (success = 0) Then
    outFile.WriteLine("Failed to load attachment file.")
    WScript.Quit
End If

' Indicate the content-type according to the file content type.
' Common content-types are:   image/jpg, image/png, application/pdf, application/zip, application/msword
' If you don't know, use application/octet-stream
' resp is a Chilkat.HttpResponse
Set resp = http.PBinaryBd("POST",url,bd,"image/jpg",0,0)
If (http.LastMethodSuccess <> 1) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Response Status Code: " & resp.StatusCode)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonResponse = CreateObject("Chilkat.JsonObject")
success = jsonResponse.Load(resp.BodyStr)
jsonResponse.EmitCompact = 0
outFile.WriteLine(jsonResponse.Emit())

If (resp.StatusCode <> 200) Then
    outFile.WriteLine("Failed.")

    WScript.Quit
End If

' A sample response:

' Use this online tool to generate parsing code from sample JSON: 
' Generate Parsing Code from JSON

' {
'   "Id": "35333c64-4449-457b-bf6a-1b64d538e3c7",
'   "Status": "OK",
'   "ProviderName": "Chilkat2222",
'   "DateTimeUTC": "\/Date(1587212597758)\/",
'   "Attachments": [
'     {
'       "AttachmentID": "daf106e2-8634-4349-bfcc-86c1df0793b2",
'       "FileName": "penguins.jpg",
'       "Url": "https://api.xero.com/api.xro/2.0/Invoices/0032f627-3156-4d30-9b1c-4d3b994dc921/Attachments/penguins.jpg",
'       "MimeType": "image/jpg",
'       "ContentLength": 777835
'     }
'   ]
' }

outFile.Close