(VBScript) Xero Download Attachment for an Item (such as an Invoice)

Demonstrates how to download a particular attachment for a particular Xero item.

For more information, see https://developer.xero.com/documentation/api/attachments#GET

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/xero-access-token.json")
If (success = 0) Then
    outFile.WriteLine(jsonToken.LastErrorText)
    WScript.Quit
End If

http.AuthToken = jsonToken.StringOf("access_token")

' Replace the value here with an actual tenant ID obtained from this example:
' Get Xero Tenant IDs
http.SetRequestHeader "Xero-tenant-id","83299b9e-5747-4a14-a18a-a6c94f824eb7"

http.Accept = "application/json"

' The example to list Xero attachments shows how to get attachment information.
' Here's a sample JSON response obtained form listing attachments:
' Your application can get the AttachmentID's and filenames from it.

' {
'   "Id": "24bfbcb9-dec9-4d33-835c-8f165d776766",
'   "Status": "OK",
'   "ProviderName": "Chilkat2222",
'   "DateTimeUTC": "\/Date(1587213296972)\/",
'   "Attachments": [
'     {
'       "AttachmentID": "daf106e2-8634-4349-bfcc-86c1df0793b2",
'       "FileName": "penguins.jpg",
'       "Url": "https://api.xero.com/api.xro/2.0/Invoices/0032f627-3156-4d30-9b1c-4d3b994dc921/Attachments/penguins.jpg",
'       "MimeType": "image/jpg",
'       "ContentLength": 777835
'     }
'   ]
' }

url = "https://api.xero.com/api.xro/2.0/{$Endpoint}/{$Guid}/Attachments/{$AttachmentId}"

' Endpoint can be Invoices, Receipts, CreditNotes, PurchaseOrders, etc.
success = http.SetUrlVar("Endpoint","Invoices")

' Guid is the ID of the item, such as the InvoiceID.
success = http.SetUrlVar("Guid","0032f627-3156-4d30-9b1c-4d3b994dc921")

' AttachmentId is the ID of the particular attachment to be downloaded
success = http.SetUrlVar("AttachmentId","daf106e2-8634-4349-bfcc-86c1df0793b2")

' Download the attachment data into bd.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bd = CreateObject("Chilkat.BinData")
success = http.QuickGetBd(url,bd)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Response Status Code: " & http.LastStatus)

If (http.LastStatus = 200) Then
    ' Success
    ' Save to a file..
    success = bd.WriteFile("qa_output/penguines.jpg")
Else
    ' Failed.  bd contains error information..
    outFile.WriteLine(bd.GetString("utf-8"))
End If


outFile.Close