VBScript

Get a Xero OAuth2 Access Token

See more OAuth2 Examples

Gets a Xero OAuth2 access token. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' For more information about the OAuth2, see OAuth 2.0 Authorization Flow

set oauth2 = CreateObject("Chilkat.OAuth2")

' For Xero OAuth2, set the listen port equal to the port used
' in the Authorized Redirect URL for the Client ID.
' For example, in this case the Authorized Redirect URL would be http://localhost:55568/
' Your app should choose a port not likely not used by any other application.
' See Xero OAuth2 for Desktop Apps for more information.
oauth2.ListenPort = 55568

oauth2.AuthorizationEndpoint = "https://login.xero.com/identity/connect/authorize"
oauth2.TokenEndpoint = "https://identity.xero.com/connect/token"

' Replace these with actual values.
oauth2.ClientId = "XERO_APP_OAUTH2_CLIENT_ID"
oauth2.ClientSecret = "XERO_APP_OAUTH2_CLIENT_SECRET"
oauth2.UseBasicAuth = 1

' See https://developer.xero.com/documentation/oauth2/scopes for a complete list of scopes.
' You will need to change the scopes depending on what access is needed..
oauth2.Scope = "openid profile email accounting.transactions accounting.attachments accounting.settings payroll.employees offline_access"

' Begin the OAuth2 Authorization code flow.  This returns a URL that should be loaded in a browser.
url = oauth2.StartAuth()
If (oauth2.LastMethodSuccess <> 1) Then
    outFile.WriteLine(oauth2.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("url = " & url)

' Launch the default browser on the system and navigate to the url.
' The LaunchBrowser method was added in Chilkat v10.1.2.
success = oauth2.LaunchBrowser(url)
If (success = 0) Then
    outFile.WriteLine(oauth2.LastErrorText)
    WScript.Quit
End If

' Wait for the user to approve or deny authorization in the browser.
numMsWaited = 0
Do While (numMsWaited < 90000) And (oauth2.AuthFlowState < 3)
    oauth2.SleepMs 100
    numMsWaited = numMsWaited + 100
Loop

' If the browser does not respond within the specified time, AuthFlowState will be:
' 
' 1: Waiting for Redirect - The OAuth2 background thread is waiting for the browser's redirect request.
' 2: Waiting for Final Response - The thread is awaiting the final access token response.
' In either case, cancel the background task initiated by StartAuth.

If (oauth2.AuthFlowState < 3) Then
    success = oauth2.Cancel()
    outFile.WriteLine("No response from the browser!")
    WScript.Quit
End If

' Check AuthFlowState to determine if authorization was granted, denied, or failed:
' 
' 3: Success - OAuth2 flow completed, the background thread exited, and the successful response is in AccessTokenResponse.
' 4: Access Denied - OAuth2 flow completed, the background thread exited, and the error response is in AccessTokenResponse.
' 5: Failure - OAuth2 flow failed before completion, the background thread exited, and error details are in FailureInfo.

If (oauth2.AuthFlowState = 5) Then
    outFile.WriteLine("OAuth2 failed to complete.")
    outFile.WriteLine(oauth2.FailureInfo)
    WScript.Quit
End If

If (oauth2.AuthFlowState = 4) Then
    outFile.WriteLine("OAuth2 authorization was denied.")
    outFile.WriteLine(oauth2.AccessTokenResponse)
    WScript.Quit
End If

If (oauth2.AuthFlowState <> 3) Then
    outFile.WriteLine("Unexpected AuthFlowState:" & oauth2.AuthFlowState)
    WScript.Quit
End If

' Save the full JSON access token response to a file.
set sbJson = CreateObject("Chilkat.StringBuilder")
success = sbJson.Append(oauth2.AccessTokenResponse)
success = sbJson.WriteFile("qa_data/tokens/xero-access-token.json","utf-8",0)

' The saved JSON response looks like this:

' 	{
' 	 "access_token": "...",
' 	 "token_type": "Bearer",
' 	 "expires_in": 3600,
' 	 "refresh_token": "..."
' 	}
' 
outFile.WriteLine("OAuth2 authorization granted!")
outFile.WriteLine("Access Token = " & oauth2.AccessToken)

outFile.Close