(VBScript) Verify XAdES with External File Reference

Demonstrates how to validate an XML digital signature that contains a reference to an external file. (This is one way of doing it..)

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Load the XAdES file to be validated..
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbXml = CreateObject("Chilkat.StringBuilder")
success = sbXml.LoadFile("qa_data/xml_dsig_valid_samples/externalFile/test.pdf.XAdES","utf-8")
If (success = 0) Then
    outFile.WriteLine("Failed to load XAdES input file.")
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.XmlDSig")
set validator = CreateObject("Chilkat.XmlDSig")

' Specify a set of absolute or relative directory paths to be searched for any external file references.
' Directory paths are separated by semicolon chars.
validator.ExternalRefDirs = "qa_data/externalFiles;qa_data/xml_dsig_valid_samples/externalFile;c:/someOtherDir"

success = validator.LoadSignatureSb(sbXml)
If (success = 0) Then
    outFile.WriteLine(validator.LastErrorText)
    WScript.Quit
End If

' Validate signatures as usual..
i = 0
Do While i < validator.NumSignatures
    validator.Selector = i

    valid = validator.VerifySignature(1)
    outFile.WriteLine("Signature " & (i + 1) & " and all reference digests OK = " & valid)

    i = i + 1
Loop

outFile.Close