VBScript

WordPress Create Tag

See more WordPress Examples

Demonstrates how to create a new tag in Wordpress, or to find the ID of an existing tag. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")

' Use your WordPress login, such as "admin", not the application name.
http.Login = "wp_username"
' Use the application password, such as "Nths RwVH eDJ4 weNZ orMN jabq"
' See WordPress Application Passwords Plugin
http.Password = "app_password"
http.BasicAuth = 1

' Create the tag "ChatGPT" if it does not already exist.
set json = CreateObject("Chilkat.JsonObject")
success = json.UpdateString("name","ChatGPT")

' This will create the tag if it does not yet exist.
' If the tag already exists, then a 400 status code is returned.
' If the tag deoes not yet exist, then a 201 status code is returned.
set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpJson("POST","https://cknotes.com/wp-json/wp/v2/tags",json,"application/json",resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

set jResp = CreateObject("Chilkat.JsonObject")
success = jResp.Load(resp.BodyStr)

' Check if the tag already exists..
If (resp.StatusCode = 400) Then
    If (jResp.HasMember("code") = 1) Then
        If (jResp.StringOfEquals("code","term_exists",1) = 1) Then
            ' The tag already exists.
            outFile.WriteLine("The tag already exists.")
            outFile.WriteLine("Tag ID: " & jResp.IntOf("data.term_id"))
            WScript.Quit
        End If

    End If

    ' Fall through to check for errors.
End If

' Check for errors.
If (resp.StatusCode <> 201) Then
    outFile.WriteLine(resp.BodyStr)
    outFile.WriteLine("status code = " & resp.StatusCode)
    WScript.Quit
End If

' We get here if the tag was created..
outFile.WriteLine("The tag was created.")
outFile.WriteLine("Tag ID = " & jResp.IntOf("id"))

outFile.Close