VBScript

WooCommerce OAuth 1.0a “one-legged” Authentication

See more REST Examples

Demonstrates how to use OAuth 1.0a "one legged" authentication with Woo Commerce. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' Demonstrates how to do OAuth1 authentication for a Wordpress site using Woo Commerce.

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Prepare an OAuth 1.0 object for use with the Chilkat REST API.
set oauth1 = CreateObject("Chilkat.OAuth1")
oauth1.ConsumerKey = "WOO_COMMERCE_CONSUMER_KEY"
oauth1.ConsumerSecret = "WOO_COMMERCE_CONSUMER_SECRET"

' The signature method can be HMAC-SHA1 or HMAC-SHA256
oauth1.SignatureMethod = "HMAC-SHA256"

' The OauthUrl property will need to be updated each time a request is sent.
' The domain here must match the domain passed to the Connect method (below).
' The domain must be exact.  For example, "www.your-wordpress-site.com" vs. "your-wordpress-site.com".
' One might work while the other does not..
oauth1.OauthUrl = "http://your-wordpress-site.com/wc-api/v3/orders"

' The OAuthMethod property will be set automatically when the REST request is sent.
' Setting it here is not actually necessary.
oauth1.OauthMethod = "GET"

' Generate an initial nonce so that Chilkat knows the desired size of the nonce.
success = oauth1.GenNonce(32)

set rest = CreateObject("Chilkat.Rest")

' Tell the REST object to use the OAuth1 object for authentication.
' Also, indicate that the OAuth authentication parameters should be query parameters
' and not located within the Authorization header.
bUseQueryParams = 1
success = rest.SetAuthOAuth1(oauth1,bUseQueryParams)

' Make the initial connection (without sending a request yet) to the WooCommerce endpoint at your Wordpress blog.
bTls = 0
port = 80
bAutoReconnect = 1
success = rest.Connect("your-wordpress-site.com",port,bTls,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Send a GET request to list orders.

' When the request is sent, the OAuth1 object's Timestamp and Nonce properties are automatically
' regenerated.  Also, the OAuth1 object's OauthMethod property is automatically set to the HTTP method
' used for the request (in this case it is "GET").
responseJson = rest.FullRequestNoBody("GET","/wc-api/v3/orders")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' When successful, the response status code will equal 200.
If (rest.ResponseStatusCode <> 200) Then
    ' Examine the request/response to see what happened.
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body (if any): " & responseJson)
    outFile.WriteLine("---")
    outFile.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    outFile.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    WScript.Quit
End If

outFile.WriteLine(responseJson)
outFile.WriteLine("Success.")

outFile.Close