(VBScript) Wish for Merchants -- Get OAuth2 Access Token for Desktop App

Demonstrates how to get a Wish for Merchants OAuth2 access token from a desktop application or script.

Note: This example requires Chilkat v10.1.2 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' To further clarify, see OAuth 2.0 Authorization Flow

' This example is for desktop applicatons (it is not for code that runs on a web server).

' This is the way to initially obtain the OAuth2 access token.  Afterwards it can be 
' repeatedly refreshed without user interaction, as shown in this example: Refresh Wish OAuth2 Access Token.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.OAuth2")
set oauth2 = CreateObject("Chilkat.OAuth2")

' Wish OAuth2 does not allow a localhost callback URI such as "http://localhost:<portNumber>/"
' For a desktop app, you must provide a script on your web server to redirect to "http://localhost/<portNumber>"

' Your applicaton must use your own public web server as an intermediate
' to receive and forward the redirect to localhost.
' See Using Your Web Server as an Intermediary for OAuth2 Redirect to localhost
oauth2.AppCallbackUrl = "https://yourwebserver.com/OAuth2.php"
oauth2.ListenPort = 3017

oauth2.AuthorizationEndpoint = "https://merchant.wish.com/v3/oauth/authorize"
oauth2.TokenEndpoint = "https://merchant.wish.com/api/v3/oauth/access_token"

oauth2.UncommonOptions = "EXCHANGE_CODE_FOR_TOKEN_USING_GET"

' Replace these with actual values.
oauth2.ClientId = "WISH-CLIENT-ID"
oauth2.ClientSecret = "WISH-CLIENT-SECRET"

oauth2.Scope = ""

' Begin the OAuth2 Authorization code flow.  This returns a URL that should be loaded in a browser.
url = oauth2.StartAuth()
If (oauth2.LastMethodSuccess <> 1) Then
    outFile.WriteLine(oauth2.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("url = " & url)

' Launch the default browser on the system and navigate to the url.
' The LaunchBrowser method was added in Chilkat v10.1.2.
success = oauth2.LaunchBrowser(url)
If (success = 0) Then
    outFile.WriteLine(oauth2.LastErrorText)
    WScript.Quit
End If

' Wait for the user to approve or deny authorization in the browser.
numMsWaited = 0
Do While (numMsWaited < 90000) And (oauth2.AuthFlowState < 3)
    oauth2.SleepMs 100
    numMsWaited = numMsWaited + 100
Loop

' If the browser does not respond within the specified time, AuthFlowState will be:
' 
' 1: Waiting for Redirect - The OAuth2 background thread is waiting for the browser's redirect request.
' 2: Waiting for Final Response - The thread is awaiting the final access token response.
' In either case, cancel the background task initiated by StartAuth.

If (oauth2.AuthFlowState < 3) Then
    success = oauth2.Cancel()
    outFile.WriteLine("No response from the browser!")
    WScript.Quit
End If

' Check AuthFlowState to determine if authorization was granted, denied, or failed:
' 
' 3: Success - OAuth2 flow completed, the background thread exited, and the successful response is in AccessTokenResponse.
' 4: Access Denied - OAuth2 flow completed, the background thread exited, and the error response is in AccessTokenResponse.
' 5: Failure - OAuth2 flow failed before completion, the background thread exited, and error details are in FailureInfo.

If (oauth2.AuthFlowState = 5) Then
    outFile.WriteLine("OAuth2 failed to complete.")
    outFile.WriteLine(oauth2.FailureInfo)
    WScript.Quit
End If

If (oauth2.AuthFlowState = 4) Then
    outFile.WriteLine("OAuth2 authorization was denied.")
    outFile.WriteLine(oauth2.AccessTokenResponse)
    WScript.Quit
End If

If (oauth2.AuthFlowState <> 3) Then
    outFile.WriteLine("Unexpected AuthFlowState:" & oauth2.AuthFlowState)
    WScript.Quit
End If

' Save the full JSON access token response to a file.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbJson = CreateObject("Chilkat.StringBuilder")
success = sbJson.Append(oauth2.AccessTokenResponse)
success = sbJson.WriteFile("qa_data/tokens/wish.json","utf-8",0)

' The full JSON received looks like this:
' {
'   "message": "",
'   "code": 0,
'   "data": {
'     "access_token": "15af1c191c1243b029bc1660b5c08ce7",
'     "scopes": [
'       "epc:read",
'       "epc:write",
'       "fbs:read",
'       "fbs:write",
'       "fbw:read",
'       "fbw:write",
'       "infractions:read",
'       "infractions:write",
'       "insurance:read",
'       "insurance:write",
'       "loans:read",
'       "loans:write",
'       "merchant:read",
'       "merchant:write",
'       "notifications:read",
'       "notifications:write",
'       "orders:read",
'       "orders:write",
'       "payments:read",
'       "payments:write",
'       "penalties:read",
'       "penalties:write",
'       "product_boost:read",
'       "product_boost:write",
'       "products:read",
'       "products:write",
'       "ratings:read",
'       "ratings:write",
'       "returns:read",
'       "returns:write",
'       "tickets:read",
'       "tickets:write"
'     ],
'     "merchant_id": "5eb3f605178f5be2c784fa02",
'     "expiry_time": "2020-12-17T16:55:09.594+00:00",
'     "refresh_token": "55a38e44df674a1e859891624b2c4c23"
'   }
' }

outFile.WriteLine("OAuth2 authorization granted!")
outFile.WriteLine("Access Token = " & oauth2.AccessToken)

outFile.Close