(VBScript) WebSocket through SSH Tunnel

This example shows how to establish a WebSocket connection through an SSH tunnel. The WebSocket protocol communications will be encapsulated within an SSH tunnel.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' --------------------------------------------------
' This example borrows the code from the REST through SSH Tunnel example.
' We first use the Chilkat Socket object to establish a connection to the WebSocket server through an SSH Tunnel.
' Next, the Rest object uses the Socket object for its connection.
' Finally, the WebSocket object uses the Rest object for its connection.  
' 
' Hopefully the flexibility of this architecture is easy to see.  All of the HTTP functionality of the Rest object,
' such as HTTP authentication, custom headers, etc. is available to the WebSocket.  Likewise, all of the advanced functionality
' of the Socket object is in turn available to the Rest object.  

' The high-level steps for accomplishing the task of running the WebSocket protocol through an SSH accomplished as follows:
' 1) Create the SSH tunnel using Chilkat Socket.
' 2) Open a port-forwarding channel (to the WebSocket server) within the tunnel.
' 2) Tell Rest to use the Socket object.
' 3) Tell WebSocket to use the Rest object.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Socket")
set tunnel = CreateObject("Chilkat.Socket")

sshHostname = "sftp.example.com"
sshPort = 22

' Connect to an SSH server and establish the SSH tunnel:
success = tunnel.SshOpenTunnel(sshHostname,sshPort)
If (success <> 1) Then
    outFile.WriteLine(tunnel.LastErrorText)
    WScript.Quit
End If

' Authenticate with the SSH server via a login/password
' or with a public key.
' This example demonstrates SSH password authentication.
success = tunnel.SshAuthenticatePw("mySshLogin","mySshPassword")
If (success <> 1) Then
    outFile.WriteLine(tunnel.LastErrorText)
    WScript.Quit
End If

'  OK, the SSH tunnel is setup.  Now open a channel within the tunnel.

bTls = 1
port = 443
maxWaitMs = 5000

' This returns a socket object that is a single channel within the SSH tunnel.
' The SSH channel is our logical port-forwarded connection through the SSH tunnel.
' Note: This example establishes a TLS connection to the target WebSocket server.
' (The TLS protocol will run on the logical channel within the SSH tunnel.)
' Your application can just as easily make a non-TLS connection by changing the arguments
' passed to SshOpenChannel.
' channel is a Chilkat.Socket
Set channel = tunnel.SshOpenChannel("some-websocket-server.com",port,bTls,maxWaitMs)
If (tunnel.LastMethodSuccess <> 1) Then
    outFile.WriteLine(tunnel.LastErrorText)
    WScript.Quit
End If

' Create a REST object and tell it to use the SSH channel.
' This connection is a TLS running on an SSH channel through an SSH tunnel.
' In other words, TLS is wrapped within the SSH tunnel.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")
success = rest.UseConnection(channel,0)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)

    WScript.Quit
End If

' Finally, tell our WebSocket object to use the Rest object..
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.WebSocket")
set ws = CreateObject("Chilkat.WebSocket")

' Tell the WebSocket to use this connection.
success = ws.UseConnection(rest)
If (success <> 1) Then
    outFile.WriteLine(ws.LastErrorText)
    WScript.Quit
End If

' Add the standard WebSocket open handshake headers that will be needed.
' (This adds the required HTTP request headers to the rest object.)
success = ws.AddClientHeaders()

' Add any additional headers that might be desired.
' Two common WebSocketSpecific headers are "Sec-WebSocket-Protocol" and "Origin".
success = rest.AddHeader("Sec-WebSocket-Protocol","x-some-websocket-subprotocol")
success = rest.AddHeader("Origin","http://some-websocket-server.com")

' Do the open handshake.
responseBody = rest.FullRequestNoBody("GET","/something")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' If successful, the HTTP response status code should be 101,
' and the response body will be empty. (If it failed, we'll have a look
' at the response body..)
statusCode = rest.ResponseStatusCode
outFile.WriteLine("Response status code: " & statusCode)

If (statusCode <> 101) Then
    outFile.WriteLine(responseBody)
    outFile.WriteLine("-- Failed because of unexpected response status code.")
    WScript.Quit
End If

' We have the expected 101 response, so let's now validate the 
' contents of the response, such as the value sent by the server in the
' Sec-WebSocket-Accept header. 
success = ws.ValidateServerHandshake()
If (success <> 1) Then
    outFile.WriteLine(ws.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("WebSocket connection successful.")

' The application may now begin sending and receiving frames on the WebSocket connection.
' (At this point, we're done with the rest object...)

outFile.Close