(VBScript) WebSocket Connect through HTTP Proxy

This example shows how to establish a WebSocket connection through an HTTP proxy server.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' --------------------------------------------------
' This example borrows the code from the REST using HTTP Proxy example.
' We first use the Chilkat Socket object to establish a connection to the WebSocket server through an HTTP proxy.
' Next, the Rest object uses the Socket object for its connection.
' Finally, the WebSocket object uses the Rest object for its connection.  
' 

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Socket")
set socket = CreateObject("Chilkat.Socket")

' Set the HTTP proxy domain or IP address, and port.
socket.HttpProxyHostname = "192.168.1.79"
socket.HttpProxyPort = 808

' Provide authentication to the HTTP proxy, if needed.
socket.HttpProxyUsername = "HTTP_PROXY_LOGIN"
socket.HttpProxyPassword = "HTTP_PROXY_PASSWORD"
socket.HttpProxyAuthMethod = "Basic"

' Indicate that HTTP requests (i.e. the WebSocket opening handshake) will be sent over the socket.
' This is important for how the HTTP proxy connection is established.
socket.HttpProxyForHttp = 1

' Connect to the websocket server through the HTTP proxy.
bTls = 0
port = 80
maxWaitMs = 5000
success = socket.Connect("some-websocket-server.com",port,bTls,maxWaitMs)
If (success <> 1) Then
    outFile.WriteLine("Connect Failure Error Code: " & socket.ConnectFailReason)
    outFile.WriteLine(socket.LastErrorText)
    WScript.Quit
End If

' Tell the Rest object to use the connected socket.
success = rest.UseConnection(socket,1)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.WebSocket")
set ws = CreateObject("Chilkat.WebSocket")

' Tell the WebSocket to use this connection.
success = ws.UseConnection(rest)
If (success <> 1) Then
    outFile.WriteLine(ws.LastErrorText)
    WScript.Quit
End If

' Add the standard WebSocket open handshake headers that will be needed.
' (This adds the required HTTP request headers to the rest object.)
success = ws.AddClientHeaders()

' Add any additional headers that might be desired.
' Two common WebSocketSpecific headers are "Sec-WebSocket-Protocol" and "Origin".
success = rest.AddHeader("Sec-WebSocket-Protocol","x-some-websocket-subprotocol")
success = rest.AddHeader("Origin","http://some-websocket-server.com")

' Do the open handshake.
responseBody = rest.FullRequestNoBody("GET","/something")
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' If successful, the HTTP response status code should be 101,
' and the response body will be empty. (If it failed, we'll have a look
' at the response body..)
statusCode = rest.ResponseStatusCode
outFile.WriteLine("Response status code: " & statusCode)

If (statusCode <> 101) Then
    outFile.WriteLine(responseBody)
    outFile.WriteLine("-- Failed because of unexpected response status code.")
    WScript.Quit
End If

' We have the expected 101 response, so let's now validate the 
' contents of the response, such as the value sent by the server in the
' Sec-WebSocket-Accept header. 
success = ws.ValidateServerHandshake()
If (success <> 1) Then
    outFile.WriteLine(ws.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("WebSocket connection successful.")

' The application may now begin sending and receiving frames on the WebSocket connection.
' (At this point, we're done with the rest and socket objects...)

outFile.WriteLine("Success.")

outFile.Close