VBScript

Walmart Partner API Authentication (Generate a Signature for a Request)

See more RSA Examples

Demonstrates how to generate a signature for a Walmart Partner REST API call. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

consumerId = "b68d2a72...."
baseUrl = "https://marketplace.walmartapis.com/v2/feeds"
' This is your Base64 encoded private key
privateEncodedStr = "MIICeAIBADANBgkqhkiG9w0BAQEFAA......"
httpMethod = "GET"

' We need a timestamp in decimal string form representing the number of milliseconds since Jan 01 1970 UTC.
set dt = CreateObject("Chilkat.CkDateTime")
' Set bLocal = 1 for a timestamp in the local timezone.  Set bLocal = 0 for a UTC timestamp.
bLocal = 0
' This gets the timestamp in seconds, not milliseconds.
timeStampVal = dt.GetAsUnixTime(bLocal)

' Build the string to sign.
set sbStringToSign = CreateObject("Chilkat.StringBuilder")
success = sbStringToSign.Append(consumerId)
success = sbStringToSign.Append(vbLf)
success = sbStringToSign.Append(baseUrl)
success = sbStringToSign.Append(vbLf)
success = sbStringToSign.Append(httpMethod)
success = sbStringToSign.Append(vbLf)
success = sbStringToSign.AppendInt(timeStampVal)
' We add three zero's so that the timestamp value is in milliseconds.
' We don't care about accuracy down to less than a second.
' All the server cares about is that the request was signed at the current date/time
' within some reasonable margin of error (to account for systems having clocks
' that may be slightly different).
success = sbStringToSign.Append("000" & vbLf)

set privKey = CreateObject("Chilkat.PrivateKey")
' Load the private key into a private key object.
' Note: Technically the private key is not PEM because it lacks the header/footer strings
' used for PEM.  However, the LoadPem method will still accept it and load it correctly.
success = privKey.LoadPem(privateEncodedStr)
If (success = 0) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

set rsa = CreateObject("Chilkat.Rsa")
success = rsa.UsePrivateKey(privKey)
If (success = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

' We want a base64 signature string.
rsa.EncodingMode = "base64"

signatureString = rsa.SignStringENC(sbStringToSign.GetAsString(),"SHA256")
If (rsa.LastMethodSuccess = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Signature String: " & signatureString)

outFile.Close